* процедура тестирования функции "SclonFio"
close tables
if !file('sotrpageg.dbf')
   create table sotrpageg (pol n(1),fam c(15),im c(15),father c(15))
   use
endif
use sotrpageg in 0
select sotrpageg
browse && для ввода тестовых фамилий
pp = 5 && номер тестируемого падежа
local f,i,o
scan
   f = fam
   i = im
   o = Father
   SclonFio(@f,@i,@o,pp,pol,.t.)
   wait f+' '+i+' '+o window
endscan
use
return && конец процедуры тестирования функции "SclonFio"


function SclonFio && функция склонения Ф.И.О. по падежам русского языка
lparameters c_fam,c_im,c_ot,p,rod,f_sclon
*  c_fam    фамилия
*  c_im        Имя
*  c_ot        Отчество
*  p        Падеж (2,3,4,5,6 - Род., Дат., Вин., Твор., Пред. соответ-но)
*  rod        Пол (0 - муж. другое значение - жен)
*  f_sclon    Нужно ли склонение фамилии (для мужчин)
local o1,o2
* o1 - предпоследняя буква
* o2 - последняя буква
*  тест входных параметров   
   c_fam   = iif(type('c_fam')='C' and len(c_fam)>1,iif(p=6 and f_sclon,'о ','')+alltrim(c_fam),'')  
   c_im    = iif(type('c_im')='C' and len(c_im)>1,alltrim(c_im),'')
   c_ot    = iif(type('c_ot')='C' and len(c_ot)>1,alltrim(c_ot),'')
   p       = iif(type('p')='N',p,2)
   rod     = iif(type('rod')='N',rod,0)
   f_sclon = iif(type('f_sclon')='L',f_sclon,.f.)
   o1 = left(right(c_fam,2),1) && предпоследняя буква
   o2 = right(c_fam,1) && последняя буква
   if rod = 0 && муж.
      if f_sclon and !empty(c_fam)&& надо склонять фамилию
         if !(o2$'уыеаоэяию') && если на конце согласная
            do case
               case o2 = 'й' && убираем окончание 2 или 1 букву и добавляем окончание по падежу
                  c_fam = substr(c_fam,1,len(c_fam)-iif(o1$'иы',2,1)) +;
                          iif(o1$'иы',iif(p=2 or p=4,'ого',iif(p=3,'ому',iif(p=5,o1+'м','ом'))),;
                                      iif(p=2 or p=4,'я',iif(p=3,'ю',iif(p=5,'ем','е'))))
               case o2 = 'ь'
                  c_fam = substr(c_fam,1,len(c_fam)-1)+iif(p=2 or p=4,'я',iif(p=3,'ю',iif(p=5,'ем','е')))
               case o1+o2$'ец'
                  c_fam = substr(c_fam,1,len(c_fam)-2)+'ьц'+iif(p=2 or p=4,'а',iif(p=3,'у',iif(p=5,'ом','е')))
               case o1+o2$'ок'
                  c_fam = substr(c_fam,1,len(c_fam)-2)+'к'+iif(p=2 or p=4,'а',iif(p=3,'у',iif(p=5,'ом','е')))
               otherwise
                  c_fam = c_fam+iif(p=2 or p=4,'а',iif(p=3,'у',iif(p=5,'ом','е')))
            endcase
         else
            do case
               case o2 = 'я'
                  c_fam = substr(c_fam,1,len(c_fam)-1)+iif(p=2 or p=4,'и',iif(p=3,'е',iif(p=5,'ей','е')))
               otherwise
                  c_fam = c_fam
            endcase
         endif
      endif
      if !empty(c_im)
         o2 = right(c_im,1)
         if !(o2$'уыеаоэяию') && Обработка Имени
            if o2 = 'й'
               c_im = substr(c_im,1,len(c_im)-1) + iif(p=2 or p=4,'я',iif(p=3,'ю',iif(p=5,'ем','е')))
            else
               c_im = c_im + iif(p=2 or p=4,'а',iif(p=3,'у',iif(p=5,'ом','е')))
            endif            
         endif
      endif
      if !empty(c_ot)
         if !(right(c_ot,1)$'уеыаоэяию')
            c_ot = c_ot + iif(p=2 or p=4,'а',iif(p=3,'у',iif(p=5,'ем','е')))
         endif
      endif
   else && жен.
      * Обработка Фамилии
      if !empty(c_fam)
         if o2='а' && если на конце буква 'а'
            c_fam = substr(c_fam,1,len(c_fam)-1) + iif(p=2 or p=4,'у','ой')
         else
           if o2='я'
              if o1 = 'а'
                 c_fam = substr(c_fam,1,len(c_fam)-2) + iif(p=2 or p=4,'ую','ой')
              else
                 c_fam = substr(c_fam,1,len(c_fam)-1) + iif(p=2 or p=4,'и',iif(p=3,'е',iif(p=5,'ей','е')))
              endif
           endif
         endif
      endif
      if !empty(c_im)
         o2 = right(c_im,1) && Обработка Имени
         do case
            case o2 ='а'
               c_im = substr(c_im,1,len(c_im)-1) + iif(p=2 or p=4,'у',iif(p=3,'е',iif(p=5,'ой','е')))
            case o2 ='ь'
               c_im = iif(p<>5,substr(c_im,1,len(c_im)-1)+'и',c_im+'ю')
            case o2 ='я'
               c_im = substr(c_im,1,len(c_im)-1)+iif(p<>5,'и','ей')
         endcase
      endif
      if !empty(c_ot)
         if right(c_ot,1)='а' && Обработка Отчества
            c_ot = substr(c_ot,1,len(c_ot)-1) + iif(p=2 or p=4,'у',iif(p=3,'е',iif(p=5,'ой','е')))
         endif
      endif
   endif
return && SclonFio

Плеве - он и в Африке Плеве

Пол человека по отчеству русскому можно однозначно определить

могут склоняться, а могут и не склоняться

f_sclon && Нужно ли склонение фамилии (для мужчин) 

Достаточно в поисковике спросить