Set Safety Off
Clear

Local lnTestCount, m.t
lnTestCount = 10 && кол-во тестов
Local lnCount
lnCount = 100000 && Задаем размер тестовой таблицы (число записей)

Local nTime1, nTime2
Store 0 To nTime1, nTime2

_ClipText = "Суммарное время : "+CHR(13)
? "Суммарное время : "

For m.t = 1 To m.lnTestCount

    Wait Window " Тест № "+Transform(m.t) Nowait

    m.nTime1 = m.nTime1 + TestTime(1, lnCount)
    m.nTime2 = m.nTime2 + TestTime(2, lnCount)
    ? m.t, m.nTime1, m.nTime2
_ClipText = _ClipText + TRANSFORM(m.t)+CHR(9)+TRANSFORM(m.nTime1)+CHR(9)+TRANSFORM(m.nTime2)+CHR(13)

Next

_ClipText = _ClipText + "Среднее время : "+CHR(9)+TRANSFORM(m.nTime1/m.lnTestCount)+CHR(9)+TRANSFORM(m.nTime2/m.lnTestCount)+CHR(13)
? "Среднее время : ", m.nTime1/m.lnTestCount, m.nTime2/m.lnTestCount



Function TestTime
*****************
    Lparameters tnTipTest,; && 1 - вариант без запроса, 2 - запрос
    tnCount && размер таблицы

    *!* Каждый раз готовим новые таблицы

    Use In Select("tTest0")
    Use In Select("tTest1")
    Use In Select("tTest2")
    Use In Select("tTest")
    Create Table tTest0 (Id i, lPropusk l)     && таблица Эталон (без пропусков)
    Create Table tTest1 (Id i)             && таблица Случайная (с пропусками)
    Create Table tTest (Id1 i, Id2 i, iDelta i)     && таблица Отчет о пропусках

    =Rand(-1)

    Local i, lnMaxInterval
    lnMaxInterval = 2 

    For m.i = 1 To m.tnCount && Генерим таблицы
        Insert Into tTest0 (Id) Values (m.i)
        Insert Into tTest1 (Id) Values (m.tnCount*Rand())
    Next

    Select tTest1
    Index On Id Tag Id Unique

    Copy To tTest2
    Use In Select("tTest1")
    Use tTest2 Alias tTest1 Exclusive && Таблица с пропусками ID

    Local m.tStart
    tStart = Seconds()


    *!* Конец общей части

    Do Case

        Case m.tnTipTest = 1

            Index On Id Tag Id Additive

            Select tTest0
            Set Relation To Id Into tTest1
            Replace All lPropusk With .T. For Eof("tTest1")
            Set Relation Off Into tTest1
            Index On lPropusk For lPropusk Tag lP
            Go Top

            Local m.lnStart, m.lnLast, m.lnEnd
            Store Id To m.lnStart, m.lnLast, m.lnEnd

            Scan
                If Id > m.lnLast + m.lnMaxInterval
                    m.lnEnd = m.lnLast
                    Insert Into tTest (Id1, Id2, iDelta) Values (m.lnStart, m.lnEnd, m.lnEnd - m.lnStart + 1)
                    m.lnStart = Id
                Endif
                m.lnLast = Id
            Endscan

            *!* и в конце
            If Id > m.lnLast + 1
                m.lnEnd = m.lnLast
                Insert Into tTest (Id1, Id2, iDelta) Values (m.lnStart, m.lnEnd, m.lnEnd - m.lnStart + 1)
            Endif

            *!*     Select tTest1
            *!*     Go Top
            *!*     Browse Last Title "Таблица с пропусками" Nowait
            *!*
            *!*     Select tTest
            *!*     Go Top
            *!*     Browse Last Title "Таблица отчет" Nowait

        Case m.tnTipTest = 2

            *!*     CREATE CURSOR tTest1 (ID i)
            *!*     INSERT INTO tTest1 (ID) VALUES (1)
            *!*     INSERT INTO tTest1 (ID) VALUES (2)
            *!*     INSERT INTO tTest1 (ID) VALUES (4)
            *!*     INSERT INTO tTest1 (ID) VALUES (5)
            *!*     INSERT INTO tTest1 (ID) VALUES (6)
            *!*     INSERT INTO tTest1 (ID) VALUES (9)
            *!*     INSERT INTO tTest1 (ID) VALUES (10)
            *!*     INSERT INTO tTest1 (ID) VALUES (11)
            *!*     INSERT INTO tTest1 (ID) VALUES (12)
            *!*     INSERT INTO tTest1 (ID) VALUES (120)
            *!*

            Select p1.Start, p2.End ;
                FROM ;
                (Select Recno() rn, Start ;
                FROM (Select t1.Id + 1 Start ;
                FROM tTest1 t1 ;
                LEFT Join tTest1 t2 ;
                ON t1.Id = t2.Id - 1 ;
                WHERE t2.Id Is Null) a1) p1 ;
                INNER Join ;
                (Select Recno() - 1 rn, End ;
                FROM (Select t1.Id - 1 End ;
                FROM tTest1 t1 ;
                LEFT Join tTest1 t2 ;
                ON t1.Id = t2.Id + 1 ;
                WHERE t2.Id Is Null) a2) p2 ;
                ON p1.rn = p2.rn ;
                WHERE p2.End - p1.Start > m.lnMaxInterval ;
                INTO Table tTest

    Endcase

    Return Seconds()-m.tStart

Результат:

Суммарное время : 
1    0,230    0,323
2    0,462    0,646
3    0,694    0,971
4    0,925    1,293
5    1,158    1,615
6    1,387    1,936
7    1,623    2,268
8    1,854    2,604
9    2,085    2,932
10    2,319    3,260
Среднее время :     0,2319    0,3260