*  
 * Foxcell - ну типа эмулятор Excel   
 *  
    
  loFoxCell=CreateObject("FoxCell")  
  With loFoxCell  
  	With .WorkBook[1]  
  		With .Sheet[1]  
  			.Cells(1,1).Value="Ура ! Получилось"  
  			.Cells(2,1).Value=12  
  			? .Cells(1,1).Value  
  			? .Cells(2,1).Value  
  		EndWith  
  	EndWith  
  EndWith  
    
 * В последствии будет заменено на Collection  
  Define Class FoxCell as Custom  
  	Dimension WorkBook[1]  
  	Add Object WorkBook[1] as WorkBook  
  EndDefine  
    
 * В последствии будет заменено на Collection  
  Define Class WorkBook as Custom  
  	Dimension Sheet[1]  
  	Add Object Sheet[1] as Sheet 	  
  EndDefine  
    
  Define Class Sheet as Collection  
 	* Блин вот это необходимо для того что бы фокс при обращении не ругался  
 	* .Cells is not an array  
  	Dimension Cells[1,1]  
    
 	* Так как в него непосредственно ничего не пишем то никакого когда нету  
  	Procedure Cells_Assign(lnRow,lnCol)  
  	With this  
 	* Nothing to do  
  	EndWith  
  	  
    
 	* Самая "хитрая" процедура которая обманывает фокс подсовывая ему  
 	* необходимыц нам объект  
  	Procedure Cells_Access(lnRow, lnCol)  
  	With this  
 		* Это болезнь всего Fox Team любовь в "нулевым прогонам"  
 		* в первый раз фокс как бы пробует на зуб, что это за зверь  
 		* тем самым получаем lnRow=.F. и lnCol=.F. в качестве   
 		* "нулевого прогона" потом все встает на свои места  
  		If Empty(lnRow) and Empty(lnCol)  
  			Return .null.  
  		EndIf  
    
 		* ФОрмируем ключ именно символьный который требует Collection  
 		* Тем самым обеспечим себе в будущем сортировку по Колонкам  
 		* внутри строк необходимую для формирования XML файла  
  		Local lcKey  
  		lcKey=Ltrim(Str(lnRow*100000+lnCol,20))  
    
  		If Empty(This.GetKey(lcKey))  
 			* Если такой объект не найден создадим начальный  
 			* тем самым оперируем только теми ячейками которые   
 			* есть а не всей поляной сразу   
  			Local oCell  
  			oCell=CreateObject("Empty")  
  			AddProperty(oCell,"Value",.null.)  
    
  			.Add(oCell,lcKey)  
    
  		EndIf  
 		* возвращаем сформированный объект  
  		Return .Item(lcKey)  
  	EndWith  
  EndDefine