aa = '{20.12.2024}'
?Evaluate(aa)

Clear

*!* Set Step On

? "chunihin-df :"
? Str2Date_chunihin_df("20 декабря 2024 года")
? Str2Date_chunihin_df("20.12.2024")
? Str2Date_chunihin_df("20/12.2024г.")
? Str2Date_chunihin_df("20 дек 2024г.")
? Str2Date_chunihin_df("20 декабря")
? Str2Date_chunihin_df("20-12 2024 года")
? Str2Date_chunihin_df("20.12.24 г.")

? "Равиль :"
? str2date_Ravil("20 декабря 2024 года")
? str2date_Ravil("20.12.2024.")
? str2date_Ravil("20/12.2024г.")
? str2date_Ravil("20 дек 2024г.")
? str2date_Ravil("20 декабря")
? str2date_Ravil("20-12 2024 года")
? str2date_Ravil("20.12.24 г.")


*****************************************
Function Str2Date_chunihin_df && Дмитрий

LPARAMETERS tcDateLongRu

LOCAL lcDSTR, laDateParts(1)
m.lcDSTR = ALLTRIM(EVL(NVL(m.tcDateLongRu,""),""))

IF NOT BETWEEN(ALINES(m.laDateParts, m.lcDSTR, 1+4, " "), 3, 4)
    RETURN {..}
ENDIF

LOCAL lSaveDate, lSaveCentury
m.lSaveDate = SET("Date")
m.lSaveCentury = SET("Century")

SET DATE GERMAN
SET CENTURY ON

LOCAL ldDate
m.ldDate = {..}

TRY
    LOCAL lcDate
    m.lcDate = m.laDateParts[1] + ;
        "." +;
        PADL(TRANSFORM(INT((ATC(','+LEFT(STRTRAN(m.laDateParts[2],"май","мая",1,1,1), 3)+',', ",янв,фев,мар,апр,мая,июн,июл,авг,сен,окт,ноя,дек,") + 3) / 4)),2, "0") + ;
        "." +;
        m.laDateParts[3] 
        
    m.ldDate = CTOD(m.lcDate)
FINALLY
    SET DATE &lSaveDate
    SET CENTURY &lSaveCentury
ENDTRY

RETURN m.ldDate


*********************************************************
Function Str2Date_Ravil && 20.12.2024 11:39 - Мой вариант

    Lparameters tcDate

    If Empty(m.tcDate)
        Return {}
    Endif

    tcDate = Upper(Alltrim(Chrtran(tcDate, ["./-], [    ]))) && заменяю разделители на пробелы

    If !Isdigit(m.tcDate) && если первый символ не числовой, то и разбирать не хочется со стоками типа "Дуатсатова ... "))
        Return {}
    Endif

    Local ln, lnWords, lnDay, lnMonth, lnYear, ldDate
    Local Array laWords[3]

    Store 0 To lnDay, lnMonth, lnYear

    lnWords = Min(3, Getwordcount(m.tcDate)) && беру максимум 3 слова

    For ln = 1 To m.lnWords
        laWords[m.ln] = Getwordnum(m.tcDate, m.ln)
    Next

    If Empty(laWords[3])
        lnYear = Year(Date())
    Else
        lnYear = Val(laWords[3])
        Do Case
            Case Between(m.lnYear, 0, 49)
                lnYear = 2000 + m.lnYear

            Case Between(m.lnYear, 50, 99)
                lnYear = 1900 + m.lnYear
        Endcase
    Endif

    If Isdigit(laWords[2])
        lnMonth = Val(laWords[2])
        If m.lnMonth > 12
            lnMonth = 0
        Endif
    Else
        Do Case
            Case laWords[2] = "ЯНВ"
                lnMonth = 1
            Case laWords[2] = "ФЕВ"
                lnMonth = 2
            Case laWords[2] = "МАР"
                lnMonth = 3
            Case laWords[2] = "АПР"
                lnMonth = 4
            Case laWords[2] = "МА"
                lnMonth = 5
            Case laWords[2] = "ИЮН"
                lnMonth = 6
            Case laWords[2] = "ИЮЛ"
                lnMonth = 7
            Case laWords[2] = "АВГ"
                lnMonth = 8
            Case laWords[2] = "СЕН"
                lnMonth = 9
            Case laWords[2] = "ОКТ"
                lnMonth = 10
            Case laWords[2] = "НОЯ"
                lnMonth = 11
            Case laWords[2] = "ДЕК"
                lnMonth = 12
            Otherwise
                lnMonth = 0
        Endcase
    Endif
    lnDay = Val(laWords[1])
    If m.lnDay > 31
        lnDay = 0
    Endif

    If Inlist(0, m.lnDay, m.lnMonth, m.lnYear)
        ldDate = {}
    Endif

    Try &&
        ldDate = Date(m.lnYear, m.lnMonth, m.lnDay)
    Catch
        ldDate = {}
    Endtry

    Return m.ldDate

If Isdigit(laWords[2])