PROCEDURE WebKassaAuthorize
        * Пример взят отсюда: forum.foxclub.ru           
        * Доработка с параметрами моя    
        LPARAMETERS tcLogin, tcPassword  

        m.xml = ""  && условленная структура сообщения   
        TEXT TO m.xml NOSHOW PRETEXT 1+2 TEXTMERGE   
        {
        "Login" : <<tcLogin>>, 
        "Password" : <<tcPassword>>
        }
        ENDTEXT  

        m.url = This.cBaseApiUrl+'Authorize'  

        RETURN This.DoHttp(m.url, m.xml)     
    ENDPROC

    PROCEDURE DoHttp  
        LPARAMETERS tcUrl, tcXml  
        tcXml = STRCONV(tcXml,9)
        * HTTP-шлюз. Общение с сервисом осуществляется при помощи отправки HTTP-запросов на заданный адрес сервиса  
        * по протоколу HTTP методами GET/POST, проверка типа контента и валидность кодировки не осуществляется.
        *oHTTP = CREATEOBJECT("MSXML2.XMLHTTP.6.0")  
        oHTTP = CREATEOBJECT("MSXML2.XMLHTTP")  
        oHTTP.open("POST", tcUrl)      
        oHTTP.setRequestHeader("Content-Type", "application/json")  
        oHTTP.send(0h+tcXml)      
         ltStart = DATETIME()  
        *DO WHILE m.oHTTP.readyState <> 4 AND DATETIME() - m.ltStart < 30 && Таймаут подобрать по своему усмотрению  
        DO WHILE m.oHTTP.readyState <> 4      
          DOEVENTS FORCE      
        ENDDO  
        LOCAL lcResponse  
        lcResponse = ""
*!*           PUSH KEY CLEAR 
*!*           SET STEP ON 
        * Разбор ответа
        DO CASE  
            CASE m.oHTTP.readyState <> 4  
              * Не дождались ответа  
                lcResponse = "Нет ответа от сервера"
            CASE !BETWEEN(m.oHTTP.Status, 200, 299)  
              * HTTP код ошибки  
              * В теории "нормальным" считается любой код 2**, не только 200  
            *   lcResponse = "Ошибка обработки данных"
                lcResponse = m.oHTTP.responseText
                MESSAGEBOX(lcResponse)
                *This.ShowError(lcResponse)
                * Здесь надо сделать разбор ошибки
                * Хотябы вычислить её код
            OTHERWISE  
               lcResponse = m.oHTTP.responseText  
              * Можно разбирать сам "текст ответа" сервера  

        ENDCASE
            
        *m.r = m.oHTTP.responseText 
        m.r = lcResponse 
        oHTTP = .NULL.  
        *MESSAGEBOX(m.r)  
        RETURN m.r 
    ENDPROC

    PROCEDURE WebKassaCheck
        * Проверка нужен ли вообще чек (по типу платежа)
        IF !INLIST(typplat, 'N','B','K','R','S','T','F')  && Официальные типы платежей
            =MESSAGEBOX("Неофициальные документы WebKassa не обрабатывает",16+0+0,"WebKassa")
            RETURN .F.            
        ENDIF 
        * 0 = Наличные
        * 1 = Оплата картой
        * 2 = Оплата в кредит
        * 3 = Оплата тарой
        **************************************
        * Какая в данный момент актуальная фирма
        IF This.ActualFirm(kodotpr) = .F.
            RETURN .F.
        ENDIF 
        ***************************************
        IF INLIST(typplat, 'B','T')  && Безнал
            This.nPaymentType = 1
        ELSE 
            This.nPaymentType = 0     && Нал
        ENDIF 
*MESSAGEBOX(This.cToken+chr(13)+This.cUniqueNumber)
        local lnOperationType, xml, lcResponse
*       kodoper = 'OP'     typvhod = 'OP'
        *m.lnOperationType = IIF(kodoper == 'OP', 2, 3)
        m.xml = ""
        m.lcResponse = ""
        TEXT TO m.xml NOSHOW PRETEXT 1+2 TEXTMERGE   
        {
        "Token" : <<This.cToken>>, 
        "CashboxUniqueNumber" : <<This.cUniqueNumber>>,
        "OperationType" : <<This.nOperationType>>,
        "Positions" : [
        
        ENDTEXT 
        SELECT cur_webkas
        LOCAL lnKvoPos, lnSum, lnSumx, lnKvo, lcExtCheckNum
        m.lnKvoPos = RECCOUNT("cur_webkas")  && tov_dv
        STORE 0.00 TO m.lnSum, m.lnSumx
        FOR m.i = 1 TO m.lnKvoPos
            GO m.i
            m.lnSum = cena_ * kol_vo
            m.lnSumx = m.lnSumx + m.lnSum
            *m.NameTov = STRTRAN(name_tov,"/","|")
            m.NameTov = ALLTRIM(name_tov)
            m.lnTaxType = IIF(INLIST(kodotpr,"A444","1111"),0,100)  && 0-без налога, 100-НДС
            IF m.lnTaxType = 100
                m.TaxPercent = 12
                m.lnTax = (Lnds(cena_,m.TaxPercent,"N")*kol_vo)
                *m.lnTax = VAL(TRANSFORM(m.lnTax,"9 999 999.99"))
                m.lnTax=ROUND(m.lnTax,2)
*!*                   FOR di = 7 TO 2 STEP -1
*!*                       m.lnTax=ROUND(m.lnTax,di)
*!*                   ENDFOR 
            ELSE 
                m.TaxPercent = 0
                m.lnTax = 0
            ENDIF 
            TEXT TO m.xml ADDITIVE NOSHOW PRETEXT 1+2 TEXTMERGE 
                {
                    "Count" : <<kol_vo>>,
                    "Price" : <<cena_>>,
                    "TaxPercent" : <<m.TaxPercent>>,
                    "Tax" : <<m.lnTax>>,
                    "TaxType" : <<m.lnTaxType>>,
                    "PositionName" : <<'"'+ALLTRIM(m.NameTov)+'"'>>,
                    "PositionCode" : <<'"'+TRANSFORM(m.i)+'"'>>,
                    "UnitCode" : <<This.WebKassaConvertUnins(ed_iz)>>,
                    "ProductId" : <<IIF(EMPTY(kod_duty),0,ALLTRIM(kod_duty))>>
                }<<IIF(m.i < m.lnKvoPos,",","")>>
            ENDTEXT 
        ENDFOR 
        m.lcExtCheckNum = kodotpr+"-"+ALLTRIM(nompp) + "-" + DTOS(dtoper)
        TEXT TO m.xml ADDITIVE NOSHOW PRETEXT 1+2 TEXTMERGE 
             ],
            "Payments" : [
                {
                    "Sum" : <<IIF(This.nPaymentType = 1, m.lnSumx, 0)>>,
                    "PaymentType" : 1
                }, 
                {
                    "Sum" : <<IIF(This.nPaymentType = 0, m.lnSumx, 0)>>,
                    "PaymentType" : 0
                }
            ],    
            "RoundType" : 0,
            "ExternalCheckNumber" : <<'"'+m.lcExtCheckNum+'"'>>            
        }
        ENDTEXT  
*STRTOFILE(m.xml,"c:\ProgVFP\Test\KKM\webkassa\Test\wkass.txt")
        m.url = This.cBaseApiUrl+'Check'  
        *m.xml = "["+m.xml+"]"
        m.lcResponse = This.DoHttp(m.url, m.xml)
*       MESSAGEBOX(m.lcResponse)
*STRTOFILE(m.lcResponse,"c:\ProgVFP\Test\KKM\webkassa\Test\Check.txt")
*STRTOFILE(m.lcResponse,"c:\ProgVFP\Test\KKM\webkassa\Test\Error.txt")
*STRTOFILE(m.lcResponse,ADDBS(goApp.pathmydocuments + 'Saved')+"\Ticket.txt")
        LOCAL llSuccess, lcTicketPrintUrl, lcLocalResponse
        DO CASE 
            CASE ATC("Data", m.lcResponse) > 0
                * Даже в этом случае могут быть ошибки и их надо проверить
                IF ATC("Errors", m.lcResponse) > 0
                    m.llSuccess = .F.
                    m.lcResponse = [{"]+STREXTRACT(m.lcResponse,["],[}],63)+[}]
                    This.ShowError(m.lcResponse)
                ELSE 
                    m.lcLocalResponse = m.lcResponse
                    *STRTOFILE(m.lcLocalResponse,"c:\ProgVFP\Test\KKM\webkassa\Test\LocResp.txt")
                    m.lcResponse = STREXTRACT(m.lcResponse,["],["],61)
                    m.lcTicketPrintUrl = m.lcResponse
                    m.llSuccess = .T.
                ENDIF 
            CASE ATC("Errors", m.lcResponse) > 0
                This.ShowError(m.lcResponse)
        ENDCASE 
        IF m.llSuccess = .T.
            *MESSAGEBOX(m.lcTicketPrintUrl)
*               m.lcTicketPrintUrl = strtran(m.lcTicketPrintUrl,"https://kkm","https://devkkm")  && Б боевом режиме убрать замену

*!*                   Declare INTEGER ShellExecute IN Shell32 INTEGER, STRING @, STRING @, ; 
*!*                   STRING @, STRING @, SHORT
*!*                   ShellExecute(0, "open", m.lcTicketPrintUrl, "", "", 1)
*           MESSAGEBOX(m.lcTicketPrintUrl)    
            LOCAL lcstatus, lcconsole, lctalk
            lcstatus = SET("STATUS BAR")
            lcconsole = SET("CONSOLE")
            lctalk = SET("TALK")
            SET STATUS BAR OFF 
            SET CONSOLE OFF 
            SET TALK OFF
            TRY 
                m.lcLocalPrintUrl = This.MakeLocalFile(m.lcLocalResponse)
                DO FORM frm_webkassa WITH m.lcLocalPrintUrl
            CATCH     
                DO FORM frm_webkassa WITH m.lcTicketPrintUrl
            ENDTRY 
            SET STATUS BAR &lcstatus
            SET CONSOLE &lcconsole 
            SET TALK &lctalk
        ENDIF 
        RETURN m.llSuccess
    ENDPROC