* где-то в начале
seleсt * from таблица_с_настройками_и_как_угодно_обозванная into cursor settings readwrite
use in таблица_с_настройками_и_как_угодно_обозванная

* где-то в конце
select * from settings into table таблица_с_настройками_и_как_угодно_обозванная

******************************************
* Class Settings
******************************************
Define Class Settings As Custom
    Protected settingsProvider

    Procedure Init(toSettingsProvider As Object)
    This.settingsProvider = toSettingsProvider
    This.Reload()
    Endproc

    Procedure Destroy()
    This.Save()
    Endproc

    Procedure Reload
    Local laItem, laProperty(1), luValue
    = Amembers(laProperty, This, 0, 'U')
    For Each laItem In laProperty
        If(This.settingsProvider.Deserialize(laItem, @luValue) = ERROR_SUCCESS)
            This.AddProperty(laItem, luValue)
        Endif
    Endfor
    Endproc

    Procedure Save
    Local laItem, laProperty(1)
    = Amembers(laProperty, This, 0, 'U')
    For Each laItem In laProperty
        If(laItem != "SETTINGSPROVIDER")
            This.settingsProvider.Serialize(laItem, Getpem(This, laItem))
        Endif
    Endfor
    Endproc

Enddefine

******************************************
* Class mySettings
******************************************
Define Class mySettings As Settings
    myProperty = "default"
    appPath = "C:"

    Procedure Error(tnError As Long, tcMethod As String, tnLine As Long)
    ? tnError, tcMethod, tnLine
*
*THROW eSettingsException
    Endproc

    Procedure Show
    Local laItem, laProperty(1)
    = Amembers(laProperty, This, 0, 'U')
    For Each laItem In laProperty
        If(laItem != "SETTINGSPROVIDER")
            ? laItem, Getpem(This, laItem)
        Endif
    Endfor
    Endproc

Enddefine

******************************************
* Class SettingsProvider
******************************************
Define Class SettingsProvider As oldinireg
    iniFile = "C:\temp\ini.ini"
    iniSection = "Common"

    Procedure Serialize(tcProperty As String, tuValue As Variant @) As Long
    Return This.WriteIniEntry(tuValue, This.iniSection, tcProperty, This.iniFile)
    Endproc

    Procedure Deserialize(tcProperty As String, tuValue As Variant @)  As Long
    Return This.GetIniEntry(@tuValue, This.iniSection, tcProperty, This.iniFile)
    Endproc

Enddefine

******************************************
* Class SettingsProviderReg
******************************************
Define Class SettingsProviderReg As registry
    lookUpKey  = "Software\MyApp\"
    regKey = HKEY_CURRENT_USER

    Procedure Serialize(tcProperty As String, tuValue As Variant @) As Long
    Local retVal
    This.OpenKey(This.lookUpKey,This.regKey, .T.)
    retVal = This.SetKeyValue(tcProperty, @tuValue)
    This.CloseKey()
    Return retVal
    Endproc

    Procedure Deserialize(tcProperty As String, tuValue As Variant @)  As Long
    Local retVal
    This.OpenKey(This.lookUpKey,This.regKey)
    retVal = This.GetKeyValue(tcProperty, @tuValue)
    This.CloseKey()
    Return retVal
    Endproc

Enddefine

oProvider = Createobject("SettingsProvider")
oProvider.iniFile = "C:\temp\ini.ini"

oSettings = Createobject("mySettings", oProvider)

oSettings.Show()

oProvider = Createobject("SettingsProviderReg")
oProvider.lookUpKey  = "Software\MyApp\"
oProvider.regKey = HKEY_CURRENT_USER

oSettings = Createobject("mySettings", oProvider)

oSettings.Show()