:: Visual Foxpro, Foxpro for DOS
• Войти
Страницы:  1 2 3
Re: Запрет возврата на предыдущую страницу в web-контроле
Berloga

Сообщений: 72
Откуда: Нефтекамск
Дата регистрации: 19.12.2007
Berloga
22.04.11 13:58:50
Помогите кто чем может. Как самым простым способом можно реализовать переход по закладкам внутри страницы? Что-то вроде этого en.wikipedia.org . Пример прилагается (не фига не работающий разумеется). 
LOCAL FormForum

FormForum=CREATEOBJECT("forum")

FormForum.Show(1)



DEFINE CLASS forum AS form

    Top = 0

    Left = 0

    Height = 250

    Width = 294

    DoCreate = .T.

    Caption = "Закладка внутри страницы"

    Name = "forum"

    ADD OBJECT oie AS olecontrol WITH ;

        Top = 26, ;

        Left = 1, ;

        Height = 223, ;

        Width = 292, ;

        Anchor = 15, ;

        Name = "OIE", ;

        OleClass = "Shell.Explorer.2"

    ADD OBJECT id AS spinner WITH ;

        Height = 24, ;

        KeyboardHighValue = 100, ;

        KeyboardLowValue = 1, ;

        Left = 1, ;

        SpinnerHighValue = 100, ;

        SpinnerLowValue =   1, ;

        Top = 1, ;

        Width = 121, ;

        Name = "Id"

    ADD OBJECT go AS commandbutton WITH ;

        Top = 0, ;

        Left = 123, ;

        Height = 27, ;

        Width = 85, ;

        Caption = "Перейти", ;

        Name = "go"

    ADD OBJECT page AS commandbutton WITH ;

        Top = 0, ;

        Left = 208, ;

        Height = 27, ;

        Width = 85, ;

        Caption = "Обновить", ;

        Name = "page"

    PROCEDURE create_page

        LOCAL lnI

        WITH this.oie.document

            .open()

            .Writeln([<html><body topmargin=0 leftmargin=0><table border=0>])

            FOR lnI=1 TO 100

                .Writeln([<tr><td id="]+TRANSFORM(lnI)+["><div align='justify'>]+;

                    REPLICATE(TRANSFORM(lnI)+" ",100)+[</div></td></tr>])

            ENDFOR

            .Writeln([</table></body></html>])

            .close()

        ENDWITH

    ENDPROC

    PROCEDURE oie.Init

        this.navigate("about:blank")

        this.Parent.create_page()

    ENDPROC

    PROCEDURE go.Click

        WITH thisform

            ACTIVATE SCREEN

            ? "Переход на", .id.value

            .oIE.navigate([#]+LTRIM(STR(.id.value)))

*!*           Что здесь нужно написать, чтоб работал переход на нужную ячейку?

        ENDWITH

    ENDPROC

    PROCEDURE page.Click

        this.Parent.create_page()

    ENDPROC

ENDDEFINE



Исправлено 1 раз(а). Последнее : Berloga, 22.04.11 14:01
Ratings: 0 negative/0 positive
Re: Запрет возврата на предыдущую страницу в web-контроле
piva

Сообщений: 18655
Откуда: Курган
Дата регистрации: 24.03.2004
piva
22.04.11 14:31:58
Local FormForum  

  FormForum=CREATEOBJECT("forum")  

  FormForum.Show(1)  

    

  DEFINE CLASS forum AS form  

      Top = 0  

      Left = 0  

      Height = 250  

      Width = 294  

      DoCreate = .T.  

      Caption = "Закладка внутри страницы"  

      Name = "forum"  

      ADD OBJECT oie AS olecontrol WITH ;  

          Top = 26, ;  

          Left = 1, ;  

          Height = 223, ;  

          Width = 292, ;  

          Anchor = 15, ;  

          Name = "OIE", ;  

          OleClass = "Shell.Explorer.2"  

      ADD OBJECT id AS spinner WITH ;  

          Height = 24, ;  

          KeyboardHighValue = 100, ;  

          KeyboardLowValue = 1, ;  

          Left = 1, ;  

          SpinnerHighValue = 100, ;  

          SpinnerLowValue =   1, ;  

          Top = 1, ;  

          Width = 121, ;  

          Name = "Id"  

      ADD OBJECT go AS commandbutton WITH ;  

          Top = 0, ;  

          Left = 123, ;  

          Height = 27, ;  

          Width = 85, ;  

          Caption = "Перейти", ;  

          Name = "go"  

      ADD OBJECT page AS commandbutton WITH ;  

          Top = 0, ;  

          Left = 208, ;  

          Height = 27, ;  

          Width = 85, ;  

          Caption = "Обновить", ;  

          Name = "page"  

      PROCEDURE create_page  

          LOCAL lnI  

          WITH this.oie  

              WITH .document  

                  .open()  

                  .Writeln([<html><body topmargin=0 leftmargin=0><table border=0>])  

                  FOR lnI=1 TO 100  

                      .Writeln([<tr><a name="]+TRANSFORM(lnI)+["></a><td><div align='justify'>]+;  

                          REPLICATE(TRANSFORM(lnI)+" ",100)+[</div></td></tr>])  

                  ENDFOR  

                  .Writeln([</table></body></html>])  

                  .close()  

              ENDWITH  

          ENDWITH  

      ENDPROC  

      PROCEDURE oie.Init  

          this.navigate("about:blank")  

          this.Parent.create_page()  

      ENDPROC  

      PROCEDURE go.Click  

          WITH thisform  

              link=LTRIM(STR(.id.value))

              ACTIVATE SCREEN  

              ? "Переход на", .id.value 

              link=.oie.document.anchors.item(LTRIM(STR(.id.value)))

              If not IsNull(link)

                  link.scrollIntoView()

              EndIf

 *!*           Что здесь нужно написать, чтоб работал переход на нужную ячейку?  

          ENDWITH  

      ENDPROC  

      PROCEDURE page.Click  

          this.Parent.create_page()  

      ENDPROC  

  ENDDEFINE


------------------
Часто бывает так, что есть над чем задуматься, а нечем.
Ratings: 0 negative/0 positive
Re: Запрет возврата на предыдущую страницу в web-контроле
Berloga

Сообщений: 72
Откуда: Нефтекамск
Дата регистрации: 19.12.2007
Berloga
22.04.11 14:38:19
piva


link=.oie.document.anchors.item(LTRIM(STR(.id.value)))

If not IsNull(link)

    link.scrollIntoView()

EndIf
Спасибо! То, что нужно.
Ratings: 0 negative/0 positive
Re: Запрет возврата на предыдущую страницу в web-контроле
piva

Сообщений: 18655
Откуда: Курган
Дата регистрации: 24.03.2004
piva
22.04.11 14:40:21
Только с твоим ID - Anchors не будет заполнятся


------------------
Часто бывает так, что есть над чем задуматься, а нечем.
Ratings: 0 negative/0 positive
Страницы:  1 2 3


:: Список Форумов•Список тем•Поиск•Войти
Извините, только зарегистрированные пользователи могут оставлять сообщения в этом форуме.

On-line: 42 akvvohinc AndyNigmatec  (Гостей: 40)
© 2000-2024 Fox Club 
Яндекс.Метрика