DO decl 
* offset to "Jobs number" member in PRINTER_INFO_2 structure 
#DEFINE cJobs_OFFSET  77 
LOCAL hPrinter, lcPrinter, lcPrnInfo, lnBufsize, lnResult 
lcPrinter = Getprinter()
*lcPrinter = GetPrnName() 
hPrinter = 0 
IF OpenPrinter(lcPrinter, @hPrinter, 0) = 0 
    ? "Unable to retrieve printer handle" 
    RETURN 
ENDIF 
lnBufsize = 4096  && provide buffer of sufficient size 
lcPrnInfo = Repli(Chr(0), lnBufsize) 
lnResult = GetPrinterA(hPrinter, 2, @lcPrnInfo, lnBufsize, @lnBufsize) 
IF lnResult = 0 
    ? "Error code:", GetLastError() 
ELSE 
    ? "Number of print jobs queued:",; 
        buf2dword(SUBSTR(lcPrnInfo, cJobs_OFFSET,4)) 
ENDIF 
= ClosePrinter(hPrinter) 
* end of main 
FUNCTION GetPrnName 
* returns default printer name from Windows Registry 
    LOCAL lcBuffer, lcPrinter, lcDriver, lcPort 
    lcBuffer = Repli(Chr(0), 120) 
    = GetProfileString("Windows", "Device", ",,,",; 
        @lcBuffer, Len(lcBuffer)) 
    lcBuffer = STRTRAN(lcBuffer, Chr(0), "") 
RETURN SUBSTR(lcBuffer, 1, AT(",", lcBuffer, 1)-1) 
PROCEDURE decl 
    DECLARE INTEGER OpenPrinter IN winspool.drv; 
        STRING pPrinterName, INTEGER @phPrinter, INTEGER pDefault 
    DECLARE INTEGER ClosePrinter IN winspool.drv INTEGER hPrinter 
    DECLARE INTEGER GetProfileString IN kernel32; 
        STRING lpApp, STRING lpKey, STRING lpDefault,; 
        STRING @lpReturnedString, INTEGER nSize 
    DECLARE INTEGER GetPrinter IN winspool.drv AS GetPrinterA; 
        INTEGER hPrinter, INTEGER Lvl, STRING @pPrinter,; 
        INTEGER cbBuf, INTEGER @pcbNeeded 
    DECLARE INTEGER GetLastError IN kernel32 
FUNCTION  buf2dword (lcBuffer) 
RETURN Asc(SUBSTR(lcBuffer, 1,1)) + ; 
    BitLShift(Asc(SUBSTR(lcBuffer, 2,1)),  8) +; 
    BitLShift(Asc(SUBSTR(lcBuffer, 3,1)), 16) +; 
    BitLShift(Asc(SUBSTR(lcBuffer, 4,1)), 24)

OpenPrinter(lcPrinter, @hPrinter, 0) = 0

GetPrinterA(hPrinter, 2, @lcPrnInfo, lnBufsize, @lnBufsize)