То что ODBC версии 6 не может работать с БД (кстати и 
с просто таблицами тоже! скажем Autoinc, ну и новые типы полей конечно)

А вот с OLE DB стоит разобраться поподробнее - может у тебя старая версия 
провайдера установлена? Хотя VFP9Beta ставит 9-ю...
AFAIK OLE DB должен работать с такими базами - конечно если собственно сами 
события не блокируют доступ к базе/таблицам.

DEFINE CLASS _db_pass AS form
    Height = 23
    Width = 260
    Desktop = .T.
    AlwaysOnTop    = .T.
    AutoCenter = .T.
    BorderStyle = 2
    Caption    = 'Введите пароль. У Вас осталось 3 попытки.'
    DoCreate = .T.
    ControlBox = .F.
    WindowType = 1
    exit_cnt = 0
    Name = "Form1"
    PROCEDURE Init
        IF _db._open_level = 1
            _db._login_ok = .F.
        ELSE 
            RETURN .F.
        ENDIF 
    ENDPROC 
    ADD OBJECT Text1 AS txt 
ENDDEFINE 
DEFINE CLASS  Txt as TextBox 
    Format = "K"
    Height = 23
    Width = 260
    PasswordChar = "*"
    cnt_login = 0
    PROCEDURE Valid
        This.cnt_login = This.cnt_login +1
        IF This.cnt_login > 2 
            MESSAGEBOX('ПАРОЛЬ НЕ ВЕРЕН!'+CHR(13)+'ВСЕ ПОПЫТКИ ИСЧЕРПАНЫ!',16,'ВНИМАНИЕ!',5000)
            bad_login()
            CANCEL 
        ENDIF 
        IF !USED('_worker')
            USE worker IN 0 ALIAS _worker AGAIN 
        ENDIF 
        SELECT _worker
        GO TOP 
        LOCATE FOR ALLTRIM(UPPER(this.Value))==ALLTRIM(UPPER(_Worker.pass))
        IF FOUND() AND !EMPTY(ALLTRIM(_Worker.pass))
            _db._user_id = _Worker.id
            _db._login_ok = .T.
            ThisForm.Release
        ELSE 
            _db._user_id = '0'
            this.Value = ''
            ThisForm.Caption = 'Введите пароль. У Вас осталось '+TRANSFORM(3-This.cnt_login)+IIF(3-This.cnt_login=2,' попытки.',' попытка.')
            RETURN .F.
        ENDIF     
    ENDPROC
ENDDEFINE 
*
PROCEDURE bad_login
    IF USED('_sys_f')
        USE IN _sys_f
    ENDIF 
    IF USED('_worker')
        USE IN _worker
    ENDIF 
    IF TYPE('_db') = 'O'
        RELEASE _db
    ENDIF 
ENDPROC
*
PROCEDURE dbc_OpenData(cDatabaseName, lExclusive, lNoupdate, lValidate)
*Immediately after DBC is opened.
SET DATABASE TO JUSTSTEM(cDatabaseName)
SET MULTILOCKS ON
IniGenGuid()
ENDPROC
*
PROCEDURE dbc_AfterOpenTable(cTableName)
*After a table or view is opened.
IF TYPE('_db') # 'O'
    IniGenGuid()
ENDIF 
IF !_db._login_ok
    IF  _db._open_level = 0
        _db._open_level = 1
    ELSE 
        _db._open_level = _db._open_level + 1
    ENDIF
    IF !USED('_sys_f')
        USE sys_f IN 0 ALIAS _sys_f AGAIN 
    ENDIF 
    SELECT _sys_f 
    IF     LEN(ALLTRIM(_db._sAt)) = 0
        _db._sAt = ''
        LOCATE FOR UPPER(ALLTRIM(_Sys_f.name)) == 'SAT'
        IF FOUND() AND !EMPTY(ALLTRIM(_Sys_f.patch))
            _db._sAt = ALLTRIM(_Sys_f.patch)
        ELSE 
            MESSAGEBOX('Переменная _sAt не создана. Требуется настройка базы данных')
            bad_login()
            CANCEL
        ENDIF 
    ENDIF
    LOCATE FOR UPPER(ALLTRIM(_Sys_f.name)) == 'SEND'
    IF FOUND() AND !EMPTY(ALLTRIM(_Sys_f.patch))
        _db._send_log = EVALUATE(ALLTRIM(_Sys_f.patch))
    ELSE 
        MESSAGEBOX('Переменная _send_log не создана. Требуется настройка базы данных')
        bad_login()
        CANCEL 
    ENDIF 
    IF _db._user_id = '0'
        IF _db._open_level = 1
            o_pass=NEWOBJECT("_db_pass")
            IF TYPE('o_pass') = 'O'
                o_pass.Show(1)
                WAIT CLEAR 
            ENDIF 
        ENDIF
    ENDIF 
    IF _db._open_level = 1 AND USED('_sys_f')
        USE IN _sys_f 
    ENDIF 
    IF _db._open_level = 1 AND USED('_worker')
        USE IN _worker 
    ENDIF 
    _db._open_level = _db._open_level - 1
    IF _db._open_level = 0 AND _db._login_ok = .F.
        USE IN (cTableName)
    ENDIF 
ENDIF 
ENDPROC 
Function IniGenGuid
PUBLIC _db
_db = CREATEOBJECT('custom')
_db.AddProperty('nStartDate_',VAL(SYS(11,CTOD("01/01/2000"))))&& starting counter date
_db.AddProperty('nd96s_',0)
_db.AddProperty('nd96d_',0)
*это мне надо для моей бд и к GUID() не имеет отношения
_db.AddProperty('_login_ok',.F.)
_db.AddProperty('_open_level',0)
_db.AddProperty('_sAt','')
_db.AddProperty('_send_log',.F.)
_db.AddProperty('_user_id','0')
*** Character chain loading - for hight-numeric number imaging
_db.AddProperty('UniString_',GetUniString()) && save string as a public variable
_db.nd96s_=TickCount() && triggering last tick value
Rand(-1) && ini Random generator via system clock 
RETURN

Сначала добавим это
PROCEDURE dbc_AfterOpenTable(cTableName)
*After a table or view is opened.
MESSAGEBOX('Привет')
ENDPROC
Работает
Еще добавим
PROCEDURE dbc_OpenData(cDatabaseName, lExclusive, lNoupdate, lValidate)
*Immediately after DBC is opened.
MESSAGEBOX('Привет')
ENDPROC
Не работает

И вообще поставте DBSETPROP('mybd',"DATABASE","DBCEvents",.T.) 
создайте файл udl для теста драйвера