#define REPORT_NAME    "XX"    && Имя Вашего отчета
#define TABLE_FOR_REPORT    "TEST"    && талица для отчета
public xForm
xForm=CreateObject('Form1')
xForm.Show()
Define Class Form1 as Form
    Width=300
    Height=400
    Page=1    && Номер страницы для просмотра
    Count=0
    * Можно Shape - но у меня с ним плохо получалось
    Add Object Canvas as Container with ;
        Width=300,;
        height=400,;
        BorderStyle=0,;
        BorderWidth=0,;
        Top=0,;
        Left=0
    Add Object rl as ReportListener
    
    Procedure Init
    With this
        .rl.PreviewContainer=.Canvas
        .rl.ListenerType=2
        .rl.QuietMode=.T.
        Use TABLE_FOR_REPORT In Select(TABLE_FOR_REPORT)
    EndWith
    Procedure Activate
    With this
        .Render()
    endwith
    Procedure Resize
    With this
        .Canvas.Height=.Height+1
        .Canvas.Width=.Width+1
        .Render()
    EndWith
    Procedure QueryUnload
    this.RemoveObject('rl')
    Procedure Render
    With this
        ** Непонятно - почему не всегда срабатывает с первого раза
        ** Вернее отрисовка теряется
        .Count=.Count+1
        Report Form REPORT_NAME object .rl range .Page,.Page
        If .Count < 2
            Report Form REPORT_NAME object .rl range .Page,.Page
            Report Form REPORT_NAME object .rl range .Page,.Page
        endif
    endwith    
    Procedure rl.OutputPage (nPageNo, eDevice,nDeviceType, nleft, nTop, nWidth, nHeight, nClipLeft,nClipTop, nClipWidth, nClipHeight)
    eDevice=this.parent.Canvas    && Наш контейнер
    nDeviceType=2    && Fox Объект
    DoDefault(nPageNo, eDevice,nDeviceType)
EndDefine