CLEAR

&& -2 - красный шум, -1 - розовый, 0 - белый, 1 - синий, 2 - фиолетовый
lnTypeNoise = -1

lnSamples = 1200
DIMENSION laSample (lnSamples)

lnWaves = 10
DIMENSION laWave (lnWaves, 3)

* Генератор волн
FOR lnCnt = 1 TO lnWaves
    laWave[lnCnt, 1] = 1 + FLOOR(RAND() * lnSamples / 10) && Волна произвольной длины
    laWave[lnCnt, 2] = RAND() * PI() * 2 && Произвольный сдвиг по фазе
    laWave[lnCnt, 3] = laWave[lnCnt, 1] ^ lnTypeNoise && Уменьшаем или увеличиваем уровень шума в зависимости от длины волны
NEXT lnCnt

* Генератор шума
lnMin = +100
lnMax = -100
FOR lnX = 1 TO lnSamples
    lnSum = 0
    FOR lnWave = 1 TO lnWaves
        lnSum = lnSum + Curve(laWave[lnWave, 1], laWave[lnWave, 2], lnX) * laWave[lnWave, 3]
    NEXT lnWave
    laSample[lnX] = lnSum && / lnWaves Вот здесь у меня вопрос.
    lnMin = MIN(lnMin, laSample[lnX])
    lnMax = MAX(lnMax, laSample[lnX])
NEXT lnX

* Вывод
lnY = 1
lnScale = _SCREEN.Height / (lnMax - lnMin) * 0.9 && Рамочку оставляем небольшую
lnOffSetY = lnScale * ABS(lnMin) + 0.05 * _SCREEN.Height && И здесь рамочку
FOR lnX = 2 TO lnSamples
    _SCREEN.Line( ;
        lnX - 1, ;
        lnOffSetY + lnScale * lnY, ;
        lnX, ;
        lnOffSetY + lnScale * laSample[lnX])
    lnY = laSample[lnX]
NEXT lnX

FUNCTION Curve
    LPARAMETERS tnFreq, ; && Частота в периодах на ширину заполняемой области
                tnPhase, ; && Сдвиг по фазе
                tnX && Что заполняем
    RETURN sin(2 * PI() * tnFreq * tnX / lnSamples + tnPhase)
ENDFUNC