oMyObject=TypeDef("DATEMIN","DATEMAX","OwnerID","CleintID")

ALANGUAGE(MyArray,2)
Browarr(@MyArray)

{CTRL+X}Browarr(@{CTRL+V}){ENTER}

*
* Name   : Array Browser
*                : This is a development tool that allows to view an array in the Browse window
*
* Note 1 : The colum Name format : <T>_<C>_<L>
*                       T - Column type, V if there are diff types of values in the column
*                       C - Column Number
*                       L - Max len requered to represent value in this column
*
* Note 2 : The BrowseArrayCursor cursor isn't closed to allow BROWSE NOWAIT
*
* Author : Sergey Berezniker    
*                : Version 1.0.2    08/28/2001
* Email  : ''.phorum_html_encode('sergeyb@isgcom.com').''
*                : This program is placed into Public domain. Comments and suggestions are welcome.
****************
* Что-то я в нем переправлял, но чё - я не помню... По-моему эту строку добавил EXTERNAL ARRAY TAARRAY
* (Aijik)
****************
LPARAMETERS taArray
EXTERNAL ARRAY TAARRAY
Local lcTalkOld, lcOldArea
lcTalkOld = SET("TALK")
SET TALK OFF
lcOldArea = SELECT()
* Make sure that parameter passed is an array
IF TYPE("taArray[1]") = "U"
        MessageBox("Please pass array by reference!", 48, PROGRAM() + " - Array Browser")
        SET TALK &lcTalkOld
        RETURN .F.
ENDIF
* Makes a cursor out of a one or two-dimensional array and browses it
LOCAL lnRows, lnCols, laStru, lnI, lnJ, lcType, lnSize
LOCAL lnDec, lcRow, llAddSize, lvValue, laStru[1], ll1d
* Controls if the MAX size of the value in the column is added 
*       to the column name
llAddSize = .T.
* Figure out the size of an array
lnRows = ALEN(taArray,1)
lnCols = MAX( ALEN(taArray,2), 1 )
ll1d = (lnCols = 1)             && Is array 1D?
DIMENSION laStru(lnCols+1, 16)
lcRow = ""
laStru = ""
* Create an array with cursor structure definition
FOR lnI = 1 TO lnCols
        lcCol = Transform(lnI)
        lvValue = taArray( 1, lni )
        laStru[ lnI, 1 ] = VARTYPE(lvValue )
        laStru[ lnI, 2 ] = "C"
        lnSize = 1
        FOR lnJ = 1 TO lnRows
                IF ll1d
                        lvValue = taArray( lnJ )
                ELSE
                        lvValue = taArray( lnJ, lnI )
                ENDIF   
                IF laStru[ lnI, 1 ] <> TYPE( "lvValue" )
                        laStru[ lnI, 1 ] = "V"
                ENDIF
                lnSize = MAX( lnSize, LEN( Transform( lvValue)))
        ENDFOR
        laStru[ lnI, 1 ] = laStru[ lnI, 1 ] + "_" + lcCol
                
        IF llAddSize
                laStru[ lnI, 1 ] = laStru[ lnI, 1 ] + "_" + Transform(lnSize)
        ENDIF   
        
        lnSize = MIN( 254, lnSize)
        
        laStru[ lnI, 3 ] = lnSize
        laStru[ lnI, 4 ] = 0
        laStru[ lnI, 5 ] = .F.
        laStru[ lnI, 6 ] = .F.
        * Create "insert into" values clause
        lcRow = lcRow + IIF(EMPTY( lcRow ), "", ", ") + ;
                        "Transform( taArray[lnI" + IIF(ll1d, "", "," +lcCol) + "] )"
        
        *lcRow = lcRow + IIF(EMPTY( lcRow ), "", ", ") + ;
                        "Transform( taArray[lnI,"+lcCol+"] )"
        
ENDFOR
*=AINSERT(laStru[1])
*DIMENSION laStru[ALEN(laStru,1)+1, ALEN(laStru,2)]
lnI = ALEN(laStru,1)
laStru[ lnI, 1 ] = "Row_______"
laStru[ lnI, 2 ] = "N"
laStru[ lnI, 3 ] = 7
laStru[ lnI, 4 ] = 0
laStru[ lnI, 5 ] = .F.
laStru[ lnI, 6 ] = .F.
lcRow = lcRow + ", 0"
* Make a cursor with fields defined by laStru
CREATE CURSOR BrowseArrayCursor FROM ARRAY laStru
* Add rows into cursor
FOR lnI = 1 TO lnRows
        INSERT INTO BrowseArrayCursor VALUES ( &lcRow )
ENDFOR
REPLACE ALL Row_______ WITH RECNO()
GO TOP
*KEYBOARD "{CTRL+F10}" CLEAR
***** Aijik *****
*!*    BROWSE 
BROWSE NORMAL
***** Aijik *****
SELECT (lcOldArea)
SET TALK &lcTalkOld
RETURN