for flooders
:: Главная :: Решения :: Статьи :: Сайт М. Дроздова :: Файловый архив :: Книга по VFP 9 :: Русский Help Online :: OFF-LINE Форум
   Лисоводы   всех   стран,  объединяйтесь !!!  

Список Форумов  :: Вопросы по 1С
  

Re: БП 3.0 Получить Адрес...
Аспид
Автор

Сообщений: 3338
Откуда: Москва
Дата: 13.04.15 15:17:53
Спасибо, кажется разобрался.
Вот как оно выглядит
  
  	MSTel =  Объект.КонтактнаяИнформация[1].Представление;  // Факт  
  	  
  	MSAdr = Объект.КонтактнаяИнформация[0].Представление;   //юр  
  	  
  	qq = Объект.КонтактнаяИнформация[2].Представление;      //почт  
  	qq1 = Объект.КонтактнаяИнформация[3].Представление;     //тел
Полагаю и т.д.

Осталось с банковскими реквизитами разобраться)))


------------------




Исправлено: Аспид, 13.04.15 15:20
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
Аспид
Автор

Сообщений: 3338
Откуда: Москва
Дата: 14.04.15 10:56:21
А все оказалось прозрачнее.
Наводкой стала подсказка, что нет этого элемента в "Объект"
  
  	MSAdr 	= ЭтаФорма.ЮрАдресКонтрагента;  
  	MSTel 	= ЭтаФорма.ТелефонКонтрагента ;  
  	MSFax	= ЭтаФорма.ФаксКонтрагента;	  
  	MSEMail	= ЭтаФорма.EmailКонтрагента;
Очень понятно и логично)


------------------
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
pasha_usue

Сообщений: 3253
Откуда: Е-бург
Дата: 14.04.15 13:12:03
Аспид
А все оказалось прозрачнее.
Наводкой стала подсказка, что нет этого элемента в "Объект"
  
  	MSAdr 	= ЭтаФорма.ЮрАдресКонтрагента;  
  	MSTel 	= ЭтаФорма.ТелефонКонтрагента ;  
  	MSFax	= ЭтаФорма.ФаксКонтрагента;	  
  	MSEMail	= ЭтаФорма.EmailКонтрагента;
Очень понятно и логично)
Ноги отрезать.

Вот репрокод, не отлаживал.
  
  &НаСервере  
  Функция ПолучитьКонтактнуюИнформацию(ЧоБрать)  
    СтрВозврата = "";  
    Для Каждого СтрКИ ИЗ Объект.КонтактнаяИнформация Цикл  
      Если СтрКИ.Тип = Перечисления.ТипыКонтактнойИнформации.Телефон И ЧоБрать = "Телефон" Тогда  
        СтрВозврата = СтрКИ.НомерТелефона;  
        Прервать;  
      ИначеЕсли СтрКИ.Тип = Перечисления.ТипыКонтактнойИнформации.Адрес И ЧоБрать = "Адрес" Тогда  
        СтрВозврата = СтрКИ.Представление;  
        Прервать;  
      КонецЕсли;  
    КонецЦикла;  
    Возврат СтрВозврата;  
  КонецФункции
Не, ну можно и с формы брать, но больше похоже на бред.
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
ssa

Сообщений: 12352
Откуда: Москва
Дата: 14.04.15 13:20:52
pasha_usue
Аспид
А все оказалось прозрачнее.
Наводкой стала подсказка, что нет этого элемента в "Объект"
  
  	MSAdr 	= ЭтаФорма.ЮрАдресКонтрагента;  
  	MSTel 	= ЭтаФорма.ТелефонКонтрагента ;  
  	MSFax	= ЭтаФорма.ФаксКонтрагента;	  
  	MSEMail	= ЭтаФорма.EmailКонтрагента;
Очень понятно и логично)
Ноги отрезать.
Ага. По самые уши!
Цитата:

Вот репрокод, не отлаживал.
  
  &НаСервере  
  Функция ПолучитьКонтактнуюИнформацию(ЧоБрать)  
    СтрВозврата = "";  
    Для Каждого СтрКИ ИЗ Объект.КонтактнаяИнформация Цикл  
      Если СтрКИ.Тип = Перечисления.ТипыКонтактнойИнформации.Телефон И ЧоБрать = "Телефон" Тогда  
        СтрВозврата = СтрКИ.НомерТелефона;  
        Прервать;  
      ИначеЕсли СтрКИ.Тип = Перечисления.ТипыКонтактнойИнформации.Адрес И ЧоБрать = "Адрес" Тогда  
        СтрВозврата = СтрКИ.Представление;  
        Прервать;  
      КонецЕсли;  
    КонецЦикла;  
    Возврат СтрВозврата;  
  КонецФункции
В свете последних известий в соседней теме вызов твоей процедуры надо ему ставить в ПослеЗаписиНаСервере и тогда все действительно станет логичным.

------------------
Лень - это неосознанная мудрость.
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
Аспид
Автор

Сообщений: 3338
Откуда: Москва
Дата: 14.04.15 17:51:31
pasha_usue
Ноги отрезать.
Не, ну можно и с формы брать, но больше похоже на бред.

Подозревал что то подобное)
Значит все не верно...

Попробую завтра твой код, и подсказки Сергея.

Хотя, в общем то не понятно, почему не верно?
Боюсь объяснения долги и сложны...
ТО же самое, что объяснить начинающему, почему вред от паблик переменных, или еще что то, что тебе очевидно.

Ясно, что плохо представляю, как "мыслят" 1С...
Ну попробуйте подсказать, может пойму)


------------------
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
ssa

Сообщений: 12352
Откуда: Москва
Дата: 14.04.15 18:04:39
Форма - средство визуализации данных, а не место их хранения. Да и на форме данные могут быть совсем не в том виде, в котором они хранятся. К тому же, как я уже указывал, в форме есть далеко не все данные. Все данные есть в таблицах. А к таблицам в управляемом приложении (в таком режиме запускается БП 3.0) есть доступ только на сервере.


------------------
Лень - это неосознанная мудрость.
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
pasha_usue

Сообщений: 3253
Откуда: Е-бург
Дата: 15.04.15 07:21:41
Аспид
pasha_usue
Ноги отрезать.
Не, ну можно и с формы брать, но больше похоже на бред.
Хотя, в общем то не понятно, почему не верно?
Боюсь объяснения долги и сложны...
ТО же самое, что объяснить начинающему, почему вред от паблик переменных, или еще что то, что тебе очевидно.

Ясно, что плохо представляю, как "мыслят" 1С...
Ну попробуйте подсказать, может пойму)
Форма это средства отображения данных. Получить данные с формы можно только при каких-то определенных условиях. И не факт, что код размещенный в одном событии получит те же данные, будучи размещенным в другом событии.
А еще можно словить в принципе неожиданные глюки. Вчера работало, работало. А завтра пользователь отключил видимость элементов формы из пользовательского интерфейса, и привет. Оптимизатор тупо не заполнит визуальные элементы формы, хотя код их заполнения в теле процедуры отработает.

А почему "послезаписи" лучше всего подходит? Это событие запускается последним из цепочки событий, обрабатываемых в модуле формы и в модуле объекта справочника. А в этих событиях разработчик может заполнять кучу служебной информации.
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
Аспид
Автор

Сообщений: 3338
Откуда: Москва
Дата: 15.04.15 10:14:47
С формой ВСЁ понял.
В общем как и во всех языках. Данные надо получать из данных, а не с формы.
Тем более, что пользователь управляет видимостью данных. (я уже с факсом с этим столкнулся, пришлось делать его видимым)

Немного понял разделение на клиенте, на сервере.
Даже понял, почему по Сергеевой подсказке, не могу получить банковские реквизиты, хотя сама структура есть, но пустая.
Просто они пишутся в другой форме, и здесь нет этих данных. (Я так понимаю)


Хотел добраться до них, по подобию кода Павла.
  
  &НаСервере    
    Функция ПолучитьБанковскуюИнформацию(ЧоБрать)    
      СтрВозврата = "";    
      Для Каждого СтрБИ ИЗ Объект.ОсновнойБанковскийСчет Цикл    
        Если СтрБИ.Тип = Справочники.БанковскиеСчета.НомерСчета И ЧоБрать = "НомерСчета" Тогда    
          СтрВозврата = СтрБИ.НомерСчета;    
          Прервать;    
  	  КонецЕсли;    
      КонецЦикла;    
      Возврат СтрВозврата;    
    КонецФункции
Фига, пишет
{Справочник.Контрагенты.Форма.ФормаЭлемента.Форма(89)}: Итератор для значения не определен
Для Каждого СтрБИ ИЗ Объект.ОсновнойБанковскийСчет Цикл

Видимо как то иначе надо?
Выборкой?
Может одной выборкой, вообще все что мне нужно получить можно?
Стоит ли?


------------------
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
ssa

Сообщений: 12352
Откуда: Москва
Дата: 15.04.15 10:33:32
Аспид
С формой ВСЁ понял.
В общем как и во всех языках. Данные надо получать из данных, а не с формы.
Тем более, что пользователь управляет видимостью данных. (я уже с факсом с этим столкнулся, пришлось делать его видимым)
Вот и чудненько!
Цитата:

Немного понял разделение на клиенте, на сервере.
Даже понял, почему по Сергеевой подсказке, не могу получить банковские реквизиты, хотя сама структура есть, но пустая.
Просто они пишутся в другой форме, и здесь нет этих данных. (Я так понимаю)
Очень может быть.
Цитата:


Хотел добраться до них, по подобию кода Павла.
  
  &НаСервере    
    Функция ПолучитьБанковскуюИнформацию(ЧоБрать)    
      СтрВозврата = "";    
      Для Каждого СтрБИ ИЗ Объект.ОсновнойБанковскийСчет Цикл    
        Если СтрБИ.Тип = Справочники.БанковскиеСчета.НомерСчета И ЧоБрать = "НомерСчета" Тогда    
          СтрВозврата = СтрБИ.НомерСчета;    
          Прервать;    
  	  КонецЕсли;    
      КонецЦикла;    
      Возврат СтрВозврата;    
    КонецФункции
Фига, пишет
{Справочник.Контрагенты.Форма.ФормаЭлемента.Форма(89)}: Итератор для значения не определен
Для Каждого СтрБИ ИЗ Объект.ОсновнойБанковскийСчет Цикл

Видимо как то иначе надо?
Угу. Не надо путать теплое с мягким. Павел привел код для получения данных и из табличной части. А ОсновноБанковскийСчет - обычный реквизит справочника и он один и к нему бессмысленно применять ДЛЯ КАЖДОГО. Какого еще КАЖДОГО в ОДНОМ реквизите?
Цитата:
Выборкой?
Можно и выборкой.
Цитата:
Может одной выборкой, вообще все что мне нужно получить можно?
Можно.
Цитата:
Стоит ли?
Возможно.
Куда копать я уже написал. Куда поместить код и и что там получить. Один раз. И для счета, и для адреса, ВСЁ там. Еще раз - не нужно изобретать и искать в 1С какие-то экзотические способы доступа к данным. Ты в фоксе так же вот методом научного тыка данные получаешь? Что тебя все уносит куда-то в неведомые дали?


------------------
Лень - это неосознанная мудрость.
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
pasha_usue

Сообщений: 3253
Откуда: Е-бург
Дата: 15.04.15 10:37:37
Аспид
Фига, пишет
{Справочник.Контрагенты.Форма.ФормаЭлемента.Форма(89)}: Итератор для значения не определен
Для Каждого СтрБИ ИЗ Объект.ОсновнойБанковскийСчет Цикл

Видимо как то иначе надо?
Правильно пишет. КонтактнаяИнформация это табличная часть элемента справочника. В табличной части много элементов, я их и перебираю соответствующим итератором. А ОсновнойБанковскийСчет это реквизит справочника (одно значение). Этот реквизит ссылается на справочник банковские счета.

1. Возможно вы обращаетесь к реквизиту на клиенте. На клиенте реквизит имеет только свое текстовое отображение. Если ваша функция исполняется &НаСервере, то Объект.ОсновнойБанковскийСчет это объект типа СправочникСсылка.БанковскиеСчета и к нему можно обращаться Объект.ОсновнойБанковскийСчет.НомерСчета, Объект.ОсновнойБанковскийСчет.Банк.КоррСчет.
2. Возможно, ОсновнойБанковскийСчет не выбран. Это проверяется функцией ЗначениеЗаполнено(Объект.ОсновнойБанковскийСчет).

Аспид
Может одной выборкой, вообще все что мне нужно получить можно?
Стоит ли?
Одной выборкой получать неудобно, так как вам нужны реквизиты табличной части. Более того, в форме элемента справочника вам полностью доступен сам объект элемента справочника.
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
Аспид
Автор

Сообщений: 3338
Откуда: Москва
Дата: 15.04.15 11:20:31
Ну загадка осталась
ЗначениеЗаполнено(Объект.ОсновнойБанковскийСчет)
возвращает ложь

Но у этого контрагента, захожу на вкладку "Банковские счета" и там заполнен. Единственный счет.
Может он не основной? (если не глупость спросил)
Как до него добраться?
Не могу понять(

Да, все выполняю, по рекомендации Сергея в
&НаСервере
Процедура ПослеЗаписиНаСервере(ТекущийОбъект, ПараметрыЗаписи)

Все остальное получил с вашей помощью)


------------------
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
ssa

Сообщений: 12352
Откуда: Москва
Дата: 15.04.15 11:48:27
Аспид
Ну загадка осталась
ЗначениеЗаполнено(Объект.ОсновнойБанковскийСчет)
возвращает ложь

Но у этого контрагента, захожу на вкладку "Банковские счета" и там заполнен. Единственный счет.
Может он не основной? (если не глупость спросил)
Как до него добраться?
Не могу понять(

Да, все выполняю, по рекомендации Сергея в
&НаСервере
Процедура ПослеЗаписиНаСервере(ТекущийОбъект, ПараметрыЗаписи)

Все остальное получил с вашей помощью)
Я специально указывал к чему надо обращаться в этой процедуре. Не к ОБЪЕКТ, а ТекущийОбъект. Ну, в конце концов, поставь точку останова в этой процедуре и выдели двойным кликом слово ТекущийОбъект и хоть до посинения обследуй содержимое этого самого ТекущийОбъект. Заодно и увидишь все реквизиты.

------------------
Лень - это неосознанная мудрость.
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
Аспид
Автор

Сообщений: 3338
Откуда: Москва
Дата: 15.04.15 12:21:50
ssa
Я специально указывал к чему надо обращаться в этой процедуре. Не к ОБЪЕКТ, а ТекущийОбъект. Ну, в конце концов, поставь точку останова в этой процедуре и выдели двойным кликом слово ТекущийОбъект и хоть до посинения обследуй содержимое этого самого ТекущийОбъект. Заодно и увидишь все реквизиты.

Все так и делаю.
и конкретно слова там
йй = ЗначениеЗаполнено(ТекущийОбъект.ОсновнойБанковскийСчет) ;
ложь

И в отладчике обследовал.
Пусто все.
Но, еще раз, захожу на вкладку "Банковские счета", там заполнено


------------------
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
pasha_usue

Сообщений: 3253
Откуда: Е-бург
Дата: 15.04.15 14:18:01
Аспид
Ну загадка осталась
ЗначениеЗаполнено(Объект.ОсновнойБанковскийСчет)
возвращает ложь

Но у этого контрагента, захожу на вкладку "Банковские счета" и там заполнен. Единственный счет.
Может он не основной? (если не глупость спросил)
Как до него добраться?
Не могу понять(
Пользователь сделал вот это:
  
  INSERT INTO БанковскиеСчета (Код, Контрагент, Счет) VALUES (1, Иванов, 12345)  
  INSERT INTO БанковскиеСчета (Код, Контрагент, Счет) VALUES (2, Иванов, 65433)

Но не сделал вот это:
  
  UPDATE Контрагенты SET ОсновнойБанковскийСчет = 2 WHERE Контрагент = Иванов

Если вам так понятнее. Список банковских счетов заполнен, но реквизит основного банковского счета не заполнен. Там кнопочка есть специальная "Использовать как основной". При нажатии на эту кнопочку как раз и заполняется ОсновнойБанковскийСчет.

Можно получить список банковских счетов соответствующим запросом.
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
Аспид
Автор

Сообщений: 3338
Откуда: Москва
Дата: 15.04.15 14:23:54
pasha_usue
Аспид
Ну загадка осталась
ЗначениеЗаполнено(Объект.ОсновнойБанковскийСчет)
возвращает ложь

Но у этого контрагента, захожу на вкладку "Банковские счета" и там заполнен. Единственный счет.
Может он не основной? (если не глупость спросил)
Как до него добраться?
Не могу понять(
Пользователь сделал вот это:
  
  INSERT INTO БанковскиеСчета (Код, Контрагент, Счет) VALUES (1, Иванов, 12345)  
  INSERT INTO БанковскиеСчета (Код, Контрагент, Счет) VALUES (2, Иванов, 65433)

Но не сделал вот это:
  
  UPDATE Контрагенты SET ОсновнойБанковскийСчет = 2 WHERE Контрагент = Иванов

Если вам так понятнее. Список банковских счетов заполнен, но реквизит основного банковского счета не заполнен. Там кнопочка есть специальная "Использовать как основной". При нажатии на эту кнопочку как раз и заполняется ОсновнойБанковскийСчет.

Можно получить список банковских счетов соответствующим запросом.

Вооот... я не только программист, я еще и пользователь 1С никакой)))
Ведь чуял, где то метку поставить надо.
Спасибо, все заработало!!!!

В порядке наглости, с удовольствием бы глянул, как получить запросом список.
Сейчас не надо. Но... для науки...


------------------
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
ssa

Сообщений: 12352
Откуда: Москва
Дата: 15.04.15 14:30:56
Аспид
В порядке наглости, с удовольствием бы глянул, как получить запросом список.
Сейчас не надо. Но... для науки...
Берешь любую консоль запросов и тренируешься. Например, Тут

------------------
Лень - это неосознанная мудрость.
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
pasha_usue

Сообщений: 3253
Откуда: Е-бург
Дата: 15.04.15 14:33:15
Аспид
ssa
Я специально указывал к чему надо обращаться в этой процедуре. Не к ОБЪЕКТ, а ТекущийОбъект. Ну, в конце концов, поставь точку останова в этой процедуре и выдели двойным кликом слово ТекущийОбъект и хоть до посинения обследуй содержимое этого самого ТекущийОбъект. Заодно и увидишь все реквизиты.

Все так и делаю.
и конкретно слова там
йй = ЗначениеЗаполнено(ТекущийОбъект.ОсновнойБанковскийСчет) ;
ложь

И в отладчике обследовал.
Пусто все.
Но, еще раз, захожу на вкладку "Банковские счета", там заполнено
Еще раз. У вас не заполнен реквизит справочника. Вам тогда лучше выбирать из подчиненного справочника Банковские счета.

Процедура опять не отлажена:
  
  &НаСервере  
  Функция ВернутьХотьКакойНибудьБанковскийСчет()  
  	СтруктураВозврата = Новый Структура("НомерСчета, ПредставлениеБанка, Бик, ВидСчета");  
  	  
  	Запрос = Новый Запрос;  
  	Запрос.Текст =   
  		"ВЫБРАТЬ РАЗРЕШЕННЫЕ ПЕРВЫЕ 1  
  		|	БанковскиеСчета.НомерСчета,  
  		|	БанковскиеСчета.Банк.Представление КАК ПредставлениеБанка,  
  		|	БанковскиеСчета.ВидСчета,  
  		|	ВЫБОР  
  		|		КОГДА БанковскиеСчета.Владелец.ОсновнойБанковскийСчет.Ссылка = БанковскиеСчета.Ссылка  
  		|			ТОГДА 1  
  		|		ИНАЧЕ 0  
  		|	КОНЕЦ КАК ЭтоОсновной,  
  		|	БанковскиеСчета.Банк.Код КАК БИК  
  		|ИЗ  
  		|	Справочник.БанковскиеСчета КАК БанковскиеСчета  
  		|ГДЕ  
  		|	БанковскиеСчета.Владелец = &Владелец  
  		|  
  		|УПОРЯДОЧИТЬ ПО  
  		|	БанковскиеСчета.ПометкаУдаления,  
  		|	ЭтоОсновной УБЫВ";  
  	  
  	Запрос.УстановитьПараметр("Владелец", Объект.Ссылка);  
  	ВыборкаДетальныеЗаписи = Запрос.Выполнить().Выбрать();	  
  	Если ВыборкаДетальныеЗаписи.Следующий() Тогда  
  		ЗаполнитьЗначенияСвойств(СтруктураВозврата, ВыборкаДетальныеЗаписи);  
  	Иначе  
  		СтруктураВозврата = Неопределено;  
  	КонецЕсли;  
  	  
  	Возврат СтруктураВозврата;  
  КонецФункции
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
pasha_usue

Сообщений: 3253
Откуда: Е-бург
Дата: 15.04.15 14:37:10
Аспид
В порядке наглости, с удовольствием бы глянул, как получить запросом список.
Сейчас не надо. Но... для науки...
Для науки я вам привел пример запроса, который получает один абы какой банковский счет по его владельцу.

Если поменять конструкцию Если ВыборкаДетальныеЗаписи.Следующий() Тогда ... КонецЕсли; на Пока ВыборкаДетальныеЗаписи.Следующий() Цикл ... КонецЦикла;, то вы получите перебор всех банковских счетов (помеченные на удаление - в конце, основной - в начале).

PS. В самом запросе надо убрать "ПЕРВЫЕ 1", что соответствует фоксу "TOP 1"



Исправлено: pasha_usue, 15.04.15 14:38
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
Аспид
Автор

Сообщений: 3338
Откуда: Москва
Дата: 15.04.15 14:56:18
Спасибо ребята!!!!
Я конечно накупил книг, почитал что то.
Скачал и просмотрел 21 день.

Но за этот топик, понимания стало гораздо больше.


------------------




Исправлено: Аспид, 15.04.15 14:56
Ratings: 0 negative/0 positive

Re: БП 3.0 Получить Адрес...
Аспид
Автор

Сообщений: 3338
Откуда: Москва
Дата: 15.04.15 15:22:19
Вот код процедуры. Может еще что через зад?
  
  &НаСервере  
  Процедура ПослеЗаписиНаСервере(ТекущийОбъект, ПараметрыЗаписи)  
  	  
  	  
  	//Запись в МС   
  	CmdMS = Новый COMОбъект("ADODB.Command");  
  	CmdMS.CommandType = 4;  
  	  
    	MStxt   =	ТекущийОбъект.Наименование;  
     	MStxtFull   = ТекущийОбъект.НаименованиеПолное;  
  	MScod1s = ТекущийОбъект.Код;  
  	MSinn = ТекущийОбъект.ИНН;  
  	MSKPP = ТекущийОбъект.КПП;                         	  
  	  
  	MSAdr 	= ПолучитьКонтактнуюИнформацию("Адрес");  
  	MSTel 	= ПолучитьКонтактнуюИнформацию("Телефон");  
  	MSFax	= ПолучитьКонтактнуюИнформацию("Факс");  
  	MSEMail	= ПолучитьКонтактнуюИнформацию("АдресЭП");  
  	  
  	//йй = ЗначениеЗаполнено(ТекущийОбъект.ОсновнойБанковскийСчет) ;  
  	  
  	MSRasch = ТекущийОбъект.ОсновнойБанковскийСчет.НомерСчета;  
  	  
  	MSBik = ТекущийОбъект.ОсновнойБанковскийСчет.Банк.Код;    
  	MSBank = ТекущийОбъект.ОсновнойБанковскийСчет.Банк.Наименование;    
  	MSKorsch = ТекущийОбъект.ОсновнойБанковскийСчет.Банк.КоррСчет;	  
  	  
  	MSParent= ТекущийОбъект.Родитель.Наименование;  
  	  
  	Фамилия		=	ТекущийОбъект.ОсновноеКонтактноеЛицо.Фамилия;  
  	Имя			=	ТекущийОбъект.ОсновноеКонтактноеЛицо.Имя;  
  	Отчество	=	ТекущийОбъект.ОсновноеКонтактноеЛицо.Отчество;  
  	MSkont		=	Фамилия+" "+Имя+" "+Отчество;  
  	MSProf	=	ТекущийОбъект.ОсновноеКонтактноеЛицо.Должность;  
    
  	MSOKPO 	= ТекущийОбъект.КодПоОКПО;	  
  	MSNote  =	Строка(СокрЛП(ТекущийОбъект.Комментарий)) ;  
  	  
  	CmdMS.CommandText = "aaaaaaa";  
  	  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("TXT",200,1,90,MStxt));  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("TXTFUll",200,1,250,MStxtFull));   
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("COD1S",129,1,9,MScod1s));	  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("INN",129,1,20,MSinn));  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("kpp",200,1,40,MSKPP));  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("Okpo",200,1,40,MSOKPO));  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("Email",200,1,50,MSEMail));  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("ADRES",200,1,250,MSAdr));  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("TEL",200,1,40,MSTel));  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("Fax",200,1,40,MSFax));  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("parent",200,1,90,MSParent));  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("kont",200,1,250,MSkont));  
  	  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("DirProf",200,1,100,MSProf));  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("MNote",200,1,250,MSNote));  
  	  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("rasch",200,1,40,MSRasch));  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("rasch",200,1,140,MSBank));  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("rasch",200,1,40,MSKorsch));  
  	CmdMS.Parameters.Append(CmdMS.CreateParameter("rasch",200,1,40,MSBik));  
  	  
  	ЗаписьВMSSQL(CmdMS);  
  	///////  
  	  
  	  
  	Если ТекущийОбъект.ДополнительныеСвойства.Свойство("ДанныеКонтактногоЛица")  
  		И НЕ ТекущийОбъект.Модифицированность() Тогда  
  		  
  		ДанныеКонтактногоЛица        = Неопределено;  
  		ПредставлениеКонтактногоЛица = Неопределено;  
  		УправлениеФормой(ЭтотОбъект);  
  		  
  	КонецЕсли;  
  	  
  КонецПроцедуры
ПолучитьКонтактнуюИнформацию - Пашина переделанная под себя
ЗаписьВMSSQL - работа с MSSQL. Соединение, execute, закрытие


------------------




Исправлено: Аспид, 15.04.15 15:22
Ratings: 0 negative/0 positive



Извините, только зарегистрированные пользователи могут оставлять сообщения в этом форуме.

On-line: 6 Taran Igor Korolyov  (Гостей: 4)

22.09.2019 23:18:09 exec: 0.48
Mem: 1.481 Mb

© 2000-2019 Fox Club 
Яндекс.Метрика