* Возвращает .t., если OpenOffice.org инсталлирован, .f. - если нет
* открытие файла
FUNCTION OOoOpenFile( cFilename )
    * change backslashes to forward slashes.
    LOCAL cURL
    cURL = "file:///" + CHRTRAN( cFilename, "\", "/" )
    LOCAL oDoc
    oDoc = OOoOpenURL( cURL )
    RETURN oDoc
ENDFUNC

PROCEDURE DoNothing__ErrorHandler( pnError, pcErrMessage, pnLineNo, pcProgramFileSys16, pcProgram, pcErrorParamSys2018 )
ENDPROC

FUNCTION OOoGetServiceManager()
    IF (TYPE([goOOoServiceManager])!="O")  OR  ISNULL( goOOoServiceManager )
        PUBLIC goOOoServiceManager
        goOOoServiceManager = CREATEOBJECT( "Com.Sun.Star.ServiceManager.1" )
    ENDIF
    RETURN goOOoServiceManager
ENDFUNC

FUNCTION OOoServiceManager_CreateInstance( cServiceName )
    LOCAL oServiceManager
    oServiceManager = OOoGetServiceManager()
    
    LOCAL oInstance
    oInstance = .NULL.

    LOCAL cOldErrHandler
    cOldErrHandler = ON( "ERROR" )
    ON ERROR = DoNothing__ErrorHandler( ERROR(), MESSAGE(), LINENO(), SYS(16), PROGRAM(), SYS(2018) )
        oInstance = oServiceManager.createInstance( cServiceName )
    ON ERROR &cOldErrHandler
    
    IF ISNULL( oInstance )
        =__OOoReleaseCachedVars()
        oServiceManager = OOoGetServiceManager()
        oInstance = oServiceManager.createInstance( cServiceName )
    ENDIF

    RETURN oInstance
ENDFUNC

FUNCTION OOoGetDesktop()
    IF (TYPE([goOOoDesktop])!="O")  OR  ISNULL( goOOoDesktop )
        PUBLIC goOOoDesktop
        goOOoDesktop = OOoServiceManager_CreateInstance( "com.sun.star.frame.Desktop" )
        * COMARRAY( goOOoDesktop, 10 ) && определяет, каким образом массив передается в com-объект    
    
    ENDIF
    RETURN goOOoDesktop
ENDFUNC

FUNCTION OOoGetCoreReflection()
    IF (TYPE([goOOoCoreReflection])!="O")  OR  ISNULL( goOOoCoreReflection )
        PUBLIC goOOoCoreReflection
        goOOoCoreReflection = OOoServiceManager_CreateInstance( "com.sun.star.reflection.CoreReflection" )
        * COMARRAY( goOOoCoreReflection, 10 ) && определяет, каким образом массив передается в com-объект

    ENDIF
    RETURN goOOoCoreReflection
ENDFUNC

FUNCTION OOoCreateStruct( cTypeName )
    * Ask service manager for a CoreReflection object.
    LOCAL oCoreReflection
    oCoreReflection = OOoGetCoreReflection()
    
    * Get the IDL Class for the type name.
    LOCAL oXIdlClass
    oXIdlClass = .NULL.

    LOCAL cOldErrHandler
    cOldErrHandler = ON( "ERROR" )
    ON ERROR = DoNothing__ErrorHandler( ERROR(), MESSAGE(), LINENO(), SYS(16), PROGRAM(), SYS(2018) )
        oXIdlClass = oCoreReflection.forName( cTypeName )
    ON ERROR &cOldErrHandler
    
    IF ISNULL( oXIdlClass )
        =__OOoReleaseCachedVars()
        oCoreReflection = OOoGetCoreReflection()
        oXIdlClass = oCoreReflection.forName( cTypeName )
    ENDIF
    
    * Create a variable to hold the created Struct.
    * Assign it some initial value.
    LOCAL oStruct
    oStruct = CREATEOBJECT( "relation" ) && assign some kind of object initially

    * Ask the class definition to create an instance.
    oXIdlClass.CreateObject( @oStruct )
    
    RETURN oStruct
ENDFUNC

FUNCTION OOoPropertyValue( cName, uValue, nHandle, nState )
    LOCAL oPropertyValue
    oPropertyValue = OOoCreateStruct( "com.sun.star.beans.PropertyValue" )
    
    oPropertyValue.Name = cName
    oPropertyValue.Value = uValue
    
    IF TYPE([nHandle])="N"
        oPropertyValue.Handle = nHandle
    ENDIF
    IF TYPE([nState])="N"
        oPropertyValue.State = nState
    ENDIF
    
    RETURN oPropertyValue
ENDFUNC

FUNCTION OOoOpenURL( cURL )
    LOCAL ARRAY aNoArgs[1]
    aNoArgs[1] = OOoPropertyValue( "ReadOnly", .F. )
    
    LOCAL oDesktop
    oDesktop = OOoGetDesktop()

    PUBLIC oDoc
    oDoc = oDesktop.LoadComponentFromUrl( cURL, "_blank", 0, @ aNoargs )

    * COMARRAY( oDoc, 10 ) && определяет, каким образом массив передается в com-объект
    
    RETURN oDoc
ENDFUNC


PROCEDURE __OOoReleaseCachedVars()
    RELEASE goOOoServiceManager, goOOoDesktop, goOOoCoreReflection
ENDPROC

* Convert a local filename to an OOo URL. 
FUNCTION OOoConvertToURL( cFilename ) 
   * Ensure leading slash. 
   IF LEFT( cFilename, 1 ) != "/" 
      cFileName = "/" + cFileName 
   ENDIF 
    
   LOCAL cURL 
   cURL = CHRTRAN( cFilename, "\", "/" )   && change backslashes to forward slashes. 
   cURL = "file://" + cURL 
   RETURN cURL
ENDFUNC

DO CASE
CASE экселевское_число_дата < 60
 дата = DATE(1900, 1, 1) + экселевское_число_дата - 1
CASE экселевское_число_дата > 60
 дата = DATE(1900, 1, 1) + экселевское_число_дата - 2
CASE экселевское_число_дата > 60
 дата = несуществующий_день_29_февраля_1900_года
ENDCASE