clear    
        
rand(-1)    
create cursor points (PointId i, coordX i, coordY i, ds b)    
for lnRow=1 to 10^5
    insert into points values (lnRow, rnd(), rnd(), 0)    
endfor    
replace all ds with sqrt(coordX^2+coordY^2)    

myX = -10
myY = 1

SELECT PointId, ABS(coordX - myX) + ABS(CoordY - myY) sum1, ds  FROM points ORDER BY 2

FUNCTION rnd    
RETURN 2000000*(rand()-.5)

CLOSE TABLES
PUBLIC lnPointX, lnPointY, lnCount, lnMinRadius, lnMinPointId
lnPointX = 310
lnPointY = 250
lnCount = 500
CLEAR
?'немного подождите, создается таблица '+LTRIM(STR(lnCount))+' точек...'
CREATE CURSOR points (PoindId i, coordX i, coordY i)  
FOR i=1 TO lnCount
    INSERT INTO points VALUES (i, INT(lnCount*RAND()),INT(lnCount*RAND()))  
ENDFOR

* с символьными переменными типа C и их функциями фокс вроде работает быстрее, 
* чем с числами (N) поэтому и решил попробовать использовать именно их:
INDEX ON STR(coordX)+STR(coordY) TAG temp
SET INDEX TO
* но похоже индексация в с этими командами вообще не сильно ускоряет поиск
CLEAR

lnStart = SECONDS()  

*
* собственно сам поиск (к сожалению эти команды при выборке из больших таблиц тормозят)
*
d = 0
DO WHILE .T.
    * грубый поиск в пошагово расширяемом от главной точки квадрате:
    LOCATE FOR BETWEEN(STR(coordX),STR(lnPointX-d),STR(lnPointX+d)) ;
                    AND BETWEEN(STR(coordY),STR(lnPointY-d),STR(lnPointY+d))
    IF FOUND()
        * первая найденная точка:
        lnRadius2 = (coordX-lnPointX)*(coordX-lnPointX)+(coordY-lnPointY)*(coordY-lnPointY)
        * ограничение области окружностью для более уточненного поиска:
        * (кажется функция возведения в степень работает медленнее, чем просто умножение)
        SET FILTER TO (coordX-lnPointX)*(coordX-lnPointX)+(coordY-lnPointY)*(coordY-lnPointY) = lnRadius2 
        * вычисление минимума внутри круга:
        CALCULATE MIN((coordX-lnPointX)*(coordX-lnPointX)+(coordY-lnPointY)*(coordY-lnPointY)) TO lnMinRadius2
        * позиционирование записи:
        LOCATE FOR (coordX-lnPointX)*(coordX-lnPointX)+(coordY-lnPointY)*(coordY-lnPointY) = lnMinRadius2
        EXIT
    ENDIF
    d = d + 1
ENDDO
*
* конец поиска
*

lnStop = SECONDS() - m.lnStart 

* строка вывода:
lnMinPointId = PoindId
lnMinRadius=SQRT(lnMinRadius2)
cTextOut = 'найдено за: ' + RTRIM(STR(lnStop,12,9),0,'0') + ;
' сек.,   мин.расстояние: ' + LTRIM(STR(lnMinRadius)) + ;
', точка: '+ LTRIM(STR(PoindId))

* но хотелось понаблюдать и как все будет выглядеть визуально, что при слишком 
* уж большом количестве на такой небольшой форме показалось явно неподходящим:

IF lnCount > 500
    CLEAR
    ? cTextOut 
    RETURN
ENDIF 

* ELSE:
* а вот рисовалка для отображения точек мне однако понравилась
* чем-то напоминает солнце и звезды во вселеной 
*
PUBLIC o1
o1 = CREATEOBJECT("frm1")  
o1.Caption = cTextOut
o1.Show()

DEFINE CLASS frm1 as form
    KeyPreview = .T.
    AutoCenter = .T.
    Height=lnCount 
    Width=lnCount 
    BackColor = RGB(0,0,0)

    ADD OBJECT lbl AS label WITH ;
        Caption = '', ;
        ForeColor = RGB(255,255,255), ;
        BackStyle = 0, ;
        Top = 0, ;
        Left = lnCount-180, ;
        Height = 30, ;
        Width = 250

    PROCEDURE Init
    LOCAL lni
        WITH thisform
        * круг обнаружения - серым:
        .ForeColor = RGB(128,128,128)
        .Circle(lnMinRadius+2,lnPointX,lnPointY)
        * если не отключить фильтр - будет лишь круг с одной/несколькоми точками
        SET FILTER TO
        * все точки на форме - белым:
        .ForeColor = RGB(255,255,255)
        lni = 1
        SCAN
            .PSet(coordX,coordY)
            lni = lni + 1
        ENDSCAN
        * основную точку - в желтый:
        .ForeColor = RGB(255,255,0)
        .PSet(lnPointX,lnPointY)
        * ближайшую к ней - в голубой:
        LOCATE FOR PoindId = lnMinPointId
        .ForeColor = RGB(0,255,255)
        .PSet(coordX, coordY)
        ENDWITH
    ENDPROC

    * для проверки можно смотреть мышкой расстояния до звезд
    * но т.к. каждая "точка" на самом деле = 4 точкам, и ее координаты определяются
    * левым верхним углом этого квадратика, то расстояние получается показать +/- 1
    PROCEDURE MouseMove
    LPARAMETERS nButton, nShift, nXCoord, nYCoord
        WITH thisform
        .lbl.Caption = 'расстояние до солнца:  ' + ;
                LTRIM(STR(SQRT((nXCoord-lnPointX)^2+(nYCoord-lnPointY)^2)))
        IF INLIST(.Point(nXCoord, nYCoord), RGB(255,255,255), RGB(0,255,255), RGB(255,255,128))
            LOCATE FOR BETWEEN(coordX, nXCoord-1, nXCoord+1) AND BETWEEN(coordY, nYCoord-1, nYCoord+1)
            .lbl.Caption = .lbl.Caption + CHR(13) + 'точка: '+ LTRIM(STR(PoindId))
        ENDIF 
        ENDWITH
    ENDPROC

    * ну это - чтобы все убиралось "легким движением руки"
    PROCEDURE KeyPress
    LPARAMETERS nKeyCode, nShiftAltCtrl
        thisform.Release()
    ENDPROC

ENDDEFINE