m.n=12      && kolichestvo jacheek
m.k=10      && kolichestvo elementov v jachejke
            && togda m.k^m.n - kolichestvo razlichnyh variantov
            && a m.k^(m.n-1) - kolichestvo povtorenij kazhdogo elementa
m.t=25      && trebuemoe kolichestvo povtorenij

local ar1(m.n, m.k)   && massiv s vozmozhnymi elementami

for m.i=1 to m.n
    for m.j=1 to m.k
        ar1(m.i, m.j)=padl(m.i,2,"0")+chr(asc('A')+m.j-1)  && naprimer
    next
next

rand(-1)

create cursor tmp (f1 N(20,0))

do while reccount("tmp")< m.t
    m.rc=reccount("tmp")
    for m.i=1 to m.t-m.rc
        insert into tmp values (rnd(0, m.k^(m.n-1)-1))
    next
    select distinct f1 from tmp into cursor tmp1
    use in tmp
    use dbf("tmp1") in 0 again alias tmp
    use in tmp1
enddo

&& v kursore tmp m.t razlichnyh chisel ot 0 do m.k^(m.n-1)-1
&& v principe mozno bylo prosto vzjatj chisla ot 0 do m.t-1,
&& no dlja loto navernoe luchshe sluchajnye

local ar2(m.n, m.k*m.t)

select tmp
scan
    ar2(1,(recno()-1)*m.k+1)=0
    for m.i=2 to m.n
        ar2(m.i,(recno()-1)*m.k+1)=int(f1/(m.k^(m.i-2)))%m.k
    next
    for m.j=2 to m.k
        for m.i=1 to m.n
            ar2(m.i,(recno()-1)*m.k+m.j)=(ar2(m.i,(recno()-1)*m.k+1)+m.j-1)%m.k
        next
    next
endscan

&& vot sobstvenno i vse, ostaljnoe - pokaz rezuljtata

create cursor tmp2 (f2 C(254))
for m.i=1 to m.k*m.t
    m.f2=""
    for m.j=1 to m.n
        m.f2=m.f2+","+ar1(m.j, ar2(m.j, m.i)+1)
    next
    insert into tmp2 values (substr(m.f2,2))
next

&& kursor sostoit iz m.k*m.t strok, kotorye mozhno razbitj na m.t blokov
&& po m.k strok v kazhdom. V kazhdom bloke kazhdyj element vstrechaetsja
&& rovno odin raz. Krome togo, postroenie kursora iskljuchaet vozmozhnostj
&& nalichija odinakovyh strok

browse




function rnd             && vozraschaet sluchajnoe celoe chislo ot m.n1 do m.n2
lparameter m.n1, m.n2
local m.n3, m.n4, m.it, m.rn
m.n3=int(m.n1)
m.n4=int(m.n2)
if m.n3>m.n4
    return -1
endif
if m.n3=m.n4
    return m.n3
endif

m.it=m.n4-m.n3+1
m.rn=m.n4+1
do while m.rn>m.n4
    m.rn=m.n3+int(rand()*m.it)
enddo
return m.rn

limit=3
CLOSE TABLES
SET DELETED OFF
SET ESCAPE ON
CREATE CURSOR loto (cell1 I, cell2 I, cell3 I)
FOR x=1 TO 2
    FOR y=11 TO 12
        FOR z=21 TO 22
            INSERT INTO loto VALUES (x, y, z)
        ENDFOR
    ENDFOR
ENDFOR
SELECT 0
CREATE CURSOR nums (num I, inuse I)
FOR x=1 TO 22
    IF INLIST(x, 1,2,11,12,21,22)
        INSERT INTO nums VALUES (x, 4)
    ENDIF
ENDFOR
CALCULATE MIN(inuse), MAX(inuse) TO m1, m2
DO WHILE NOT (m1=limit AND m2=limit)
    SELECT loto
    SCAN ALL
        SCATTER TO aa
        FOR x=1 TO 3
            SELECT nums
            LOCATE FOR num=aa(x)
            DO CASE
            CASE inuse>limit AND DELETE("loto")=.F.
                DELETE IN loto
                z=-1
            CASE inuse<limit AND DELETE("loto")
                RECALL IN loto
                z=1
            OTHERWISE
                LOOP
            ENDCASE
            FOR y=1 TO x
                LOCATE FOR num=aa(y)
                REPLACE inuse WITH inuse+z
            ENDFOR
            SELECT loto
            SKIP z
        ENDFOR
    ENDSCAN
    SELECT nums
    REPLACE ALL inuse WITH 0
    SELECT loto
    SCAN FOR DELETED()=.F.
        SCATTER TO aa
        FOR x=1 TO 3
            SELECT nums
            LOCATE FOR num=aa(x)
            REPLACE inuse WITH inuse+1
        ENDFOR
    ENDSCAN
    SELECT nums
    CALCULATE MIN(inuse), MAX(inuse) FOR DELETED()=.F. TO m1, m2
ENDDO
SET DELETED ON
SELECT loto
BROWSE

m.n=12      && kolichestvo jacheek
m.k=10      && kolichestvo elementov v jachejke
            && togda m.k^m.n - kolichestvo razlichnyh variantov
            && a m.k^(m.n-1) - kolichestvo povtorenij kazhdogo elementa
m.t=25      && trebuemoe kolichestvo povtorenij

local ar1(m.n, m.k)   && massiv s vozmozhnymi elementami

for m.i=1 to m.n
    for m.j=1 to m.k
        ar1(m.i, m.j)=padl(m.i,2,"0")+chr(asc('A')+m.j-1)  && naprimer
    next
next

rand(-1)

create cursor rn0 (f1 i)  && kursor c chislami ot 0 do m.k-1 dlja zapolnenija razrjadov
for m.i=0 to m.k-1
    insert into rn0 values (m.i)
next

create cursor tmp2 (f2 C(254))  && kursor, v kotoryj budet sobiratjsja rezuljtat


local ar2(m.n, m.k)


m.cnt=0

do while m.cnt<m.t

    for m.i=1 to m.n
        select rand(), f1 from rn0 order by 1 into cursor rn1   && chisla iz kursora rn0 peremeshivajutsja
        scan
            ar2(m.i, recn())=f1
        endscan
    next
        
    create cursor tmp1 (f2 C(254))   && kursor v kotoryj pomeschaetsja 1 blok rezuljtata
    for m.i=1 to m.k
        m.f2=""
        for m.j=1 to m.n
            m.f2=m.f2+","+ar1(m.j, ar2(m.j, m.i)+1)
        next
        insert into tmp1 values (substr(m.f2,2))
    next

    &&  proverka, net li ranee vstrechavshihsja strochek v novom bloke
    select * from tmp1 where sys(2007,tmp1.f2) in (select sys(2007,tmp2.f2) from tmp2) into array ar3

    if _tally=0 
        m.cnt=m.cnt+1
        select tmp2
        append from dbf("tmp1")
    endif
enddo


browse