#DEFINE KEYBOARD_GERMAN_ST     0x0407        && Немецкий (Стандарт)
#DEFINE KEYBOARD_ENGLISH_US     0x0409        && Английский (Соединенные Штаты)
#DEFINE KEYBOARD_FRENCH_ST     0x040c        && Французский (Стандарт)
#DEFINE KEYBOARD_RUSSIAN         0x0419        && Русский

* Выбираем раскладку, которая нам нужна
LOCAL lnNeedKeyboard
lnNeedKeyboard = KEYBOARD_RUSSIAN

* Читаем текущую раскладку клавиатуры
DECLARE INTEGER GetKeyboardLayout IN Win32API Integer
LOCAL lnCurrentKeyboard
lnCurrentKeyboard = GetKeyboardLayout(0)
* Считываем младшее слово (младшие 16 бит из 32)
lnCurrentKeyboard = BitRShift(m.lnCurrentKeyboard,16)

* Если текущая раскладка отлична от нужной
IF m.lnCurrentKeyboard <> m.lnNeedKeyboard
    * Сначала пытаемся просто активизировать нужную раскладку
    DECLARE INTEGER ActivateKeyboardLayout IN Win32API Integer, Integer
    LOCAL lnNewKeyboard
    lnNewKeyboard = ActivateKeyboardLayout(m.lnNeedKeyboard,0)

    IF m.lnNewKeyboard=0
        * Нужной раскладки клавиатуры не введено в списке альтернативных раскладок
        * Добавляем нужную раскладку
        DECLARE INTEGER LoadKeyboardLayout IN Win32API String, Integer
        * Код нужной раскладки надо трансформировать в строку вида "00000419"
        * Т.е. строка из 8 символов, где первые 4 - это нули, а последние 4 код в 16-ричной системе
        LOCAL lcNeedKeyboard
        lcNeedKeyboard = RIGHT(TRANSFORM(m.lnNeedKeyboard,"@0"),8)
        * Собственно загрузка
        m.lnNewKeyboard = LoadKeyboardLayout(m.lcNeedKeyboard,1)
        * Считываем младшее слово (младшие 16 бит из 32)
        m.lnNewKeyboard = BitRShift(m.lnNewKeyboard,16)
        IF m.lnNewKeyboard <> m.lnNeedKeyboard
            * Загрузить нужную раскладку не удалось
        ENDIF
    ENDIF
ENDIF