o=Createobject("Wscript.Shell")
x=o.Exec("cmd /c dir c:")
Do While x.Status = 0
    DoEvents
Enddo
? x.StdOut.ReadAll

o=Createobject("Wscript.Shell")
x=o.Exec("notepad.exe")
WAIT WINDOW TIMEOUT 5
x.terminate()
Do While x.Status = 0
    DoEvents
Enddo
? x.StdOut.ReadAll

LOCAL loWSS
loWSS = CreateObject("WScript.Shell")
loWSS.Run("cmd /c dir > d:/out.txt 2>&1", 0, .t.)

function call_py(sPyBody, sPyFile, sPyCmd, tWait)
    * sPyBody - py-code to execute
    * sPyFile - temporary file to save py-code
    * sPyCmd - Python exe-file (likes c:\Programs\Anaconda3\python.exe)
    * tWait - Max time to do (secs)

    * Save py-body to file
*   sPyBody    = STRCONV(sPyBody, 9)    && Convert to UTF-8 (if need)
    STRTOFILE(sPyBody, sPyFile)

    * Execute
    LOCAL sExec, oWSh, tStart, oProc
    sExec    = sPyCmd + [ "] + sPyFile + ["]
    oWSh    = CreateObject("Wscript.Shell") 
    oProc    = oWSh.Exec(sExec)        && Start...
    tStart    = SECONDS()
    DO WHILE oProc.Status = 0
        DOEVENTS
        INKEY(0.1)            && =Sleep 
        IF tStart+tWait < SECONDS()    && ...secs! Try to kill process
            oProc.terminate()
        ENDIF 
        IF tStart+tWait+1 < SECONDS()    && ...secs! Panic: process is not finished
            EXIT
        ENDIF 
    ENDDO 
    IF oProc.Status = 0            && Panic: process is not finished
        trace("SKIP! Process not finished: "+sExec)
        RETURN 
    ENDIF 

    * Show results
    LOCAL sOut, sErr
    sOut    = oProc.StdOut.ReadAll()
    sErr    = oProc.StdErr.ReadAll()
    trace(sOut)
    IF !EMPTY(sErr)
        trace(sErr)
    ENDIF 
endfunc