CLEAR

RELEASE AAA
DIMENSION AAA[1]

m.d = GETDIR()
IF EMPTY(m.d)
   RETURN
ENDIF
? aDirADIR(@AAA, ADDBS(m.d)+"*.pjx", "")  && пример.
? m.d

m.l = IIF(ALEN(AAA)=1, 0, ALEN(AAA,1))
FOR m.i=1 TO m.l
    ? AAA[m.i,1]
ENDFOR
? m.l

RETURN





FUNCTION aDirADIR
LPARAMETERS m.parMASS, m.parFile, m.parAttr, m.parFlag, m.parAppDir  && Не задавать "D" в параметре 3 (это сделается само)
PRIVATE ALL LIKE ?
m.p = PCOUNT()
#DEFINE Самовызов  aDirADIR

LOCAL m.parAttr_eff, m.parFlag_eff  && если не заданы параметры 3,4
m.parAttr_eff = IIF(m.p<3, "", m.parAttr)   && атрибуты поиска H,D... D не задавать
m.parFlag_eff = IIF(m.p<4, 0,  m.parFlag)   && 0|1|2 - UPPER Original MSDOS

LOCAL m.rekurs_put  && путь-добавок к основному пути при рекурсивном вызове. NULL в первичном вызове
m.rekurs_put = .NULL.
IF m.p>=5 .AND. !ISNULL(m.parAppDir)  && это рекурсивный вызов
   m.rekurs_put = m.parAppDir
ELSE  && первичный вызов
   EXTERNAL ARRAY parMASS  && сброс (@1) в первичном вызове
   DIMENSION parMASS[1]
   STORE "" TO parMASS
ENDIF

LOCAL m.maska, m.put  && маска файлов и первичный путь. Даже в Самовызове будем его передавать в первичном виде
m.put   = JUSTPATH(m.parFile)  && m.parFile задавать с путем и маской
m.maska = JUSTFNAME(m.parFile)

LOCAL m.put_eff  && эффективный путь (с рекурсивным подпутем)
m.put_eff = RTRIM(ADDBS(m.put) + NVL(m.rekurs_put, ""), 1, "\")  && эффективный путь, без слэша в конце

* 1. Читаем все файлы (но не директории), СОГЛАСНО МАСКЕ. Записываем имя (и пр.) в выходнй массив (@1)
RELEASE Z
***********************************************************************
m.l = ADIR(Z, ADDBS(m.put_eff) + m.maska, m.parAttr_eff, m.parFlag_eff)
***********************************************************************
m.k = IIF(ALEN(m.parMASS)=1, 0, ALEN(m.parMASS,1))  && размер выходного массива (@1)
FOR m.i=1 TO m.l  && добавляем массив файлов Z к выходному массиву (@1)
    IF EMPTY(CHRTRAN(Z[m.i,1], ".", "")) .OR. "D"$UPPER(Z[m.i,5])  && не смотрим на директории, и на корневые
       LOOP
    ENDIF
    m.k = m.k + 1
    DIMENSION m.parMASS[m.k, ALEN(Z,2)]
    FOR m.j=1 TO ALEN(Z,2)
        m.parMASS[m.k, m.j] = IIF(m.j=1, IIF(ISNULL(m.rekurs_put), "", ADDBS(m.rekurs_put)) + Z[m.i, m.j],;  && имя файла записываем С ДОБАВЛЕНИЕМ РЕКУРСИВНОГО ПУТИ
                                         Z[m.i, m.j])  && остальные элементы без изменений
    ENDFOR
ENDFOR  && добавляем массив файлов Z к выходному массиву (@1)
RELEASE Z

* 2. Читаем все директории, БЕЗ МАСКИ. Делаем Самовызов на каждом поддиректории
RELEASE Z
*************************************************************************
m.l = ADIR(Z, ADDBS(m.put_eff) + "*.*", "D"+m.parAttr_eff, m.parFlag_eff)
*************************************************************************
FOR m.i=1 TO m.l  && делаем Самовызов на каждом поддиректории Z
    IF EMPTY(CHRTRAN(Z[m.i,1], ".", "")) .OR. !"D"$UPPER(Z[m.i,5])  && смотрим только на ПОДдиректории
       LOOP
    ENDIF
    *************************************************************************
    =Самовызов(@parMASS, m.parFile, m.parAttr_eff, m.parFlag_eff,;  && рассматриваем содержимое подкаталога
               IIF(ISNULL(m.rekurs_put), "", ADDBS(m.rekurs_put)) + Z[m.i,1])  && 5й параметр даст понять самовызову, что это уже не первичный вызов, а рекурсивный. Здесь рекурсивный путь
    *************************************************************************
ENDFOR  && делаем Самовызов на каждом поддиректории Z
RELEASE Z

m.k = IIF(ALEN(m.parMASS)=1, 0, ALEN(m.parMASS,1))  && размер выходного массива (@1)

RETURN m.k
#UNDEFINE Самовызов