Функция ПолучитьСтавкуРефинансифрования()
    Определения        = Новый WSОпределения("http://www.cbr.ru/DailyInfoWebServ/DailyInfo.asmx?WSDL"); 
    Прокси            = Новый WSПрокси(Определения, "http://web.cbr.ru/", "DailyInfo", "DailyInfoSoap"); 
    ТипWSПараметра    = Прокси.ФабрикаXDTO.Пакеты.Получить("http://web.cbr.ru/").Получить("AllDataInfoXML"); 
    WSПараметр        = Прокси.ФабрикаXDTO.Создать(ТипWSПараметра); 
    РезультатXDTO     = Прокси.AllDataInfoXML(WSПараметр); 
    
    КлючеваяСтавка = Число(РезультатXDTO.AllDataInfoXMLResult.AllData.KEY_RATE.val);
    
    Возврат КлючеваяСтавка;
    
КонецФункции

local loHTTP, lcRequest, lcResponse

TEXT TO lcRequest TEXTMERGE NOSHOW
<?xml version="1.0" encoding="utf-8"?>
<soap12:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap12="http://www.w3.org/2003/05/soap-envelope">
  <soap12:Body>
    <MainInfoXML xmlns="http://web.cbr.ru/" />
  </soap12:Body>
</soap12:Envelope>
ENDTEXT

loHTTP = CREATEOBJECT("Msxml2.XMLHTTP")
With loHTTP
  .Open("POST", 'http://www.cbr.ru/DailyInfoWebServ/DailyInfo.asmx', .F.)
  .setRequestHeader("Content-Type", "application/soap+xml; charset=utf-8")
  .setRequestHeader("Content-length", LTRIM(STR(LEN(lcRequest))))
  .Send(lcRequest)
  Do While .readyState # 4
    doevents force
  Enddo
  lcResponse = .responseText
Endwith
*strtofile(lcResponse, [MainInfo.XML])

local loXDOM, loNode
loXDOM = CREATEOBJECT('MSXML2.DOMDocument')
loXDOM.loadXML(lcResponse)
loNode = loXDOM.selectSingleNode("//stavka_ref")

with loNode
  ?.getAttribute("Title")
  ?.getAttribute("Date")
  ?.Text
endwith

<KEY_RATE Title="Действующая ключевая ставка" val="7.5" date="12.02.2018" />
<KEY_RATE_FUTURE Title="Новое значение ключевой ставки (справочно)" val="7.5" newdate="12.02.2018" />
<REF_RATE Title="Ставка рефинансирования (Значение соответствует значению ключевой ставки Банка России)" val="7.5" />

Rate=7.75
NewRate=7.50
NewRateStart=12.02.2018
NextCheck=24.03.2018

<KEY_RATE Title="Действующая ключевая ставка" val="7.5" date="12.02.2018" />
<KEY_RATE_FUTURE Title="Новое значение ключевой ставки (справочно)" val="7.25" newdate="26.03.2018" />

****   / "стандартные" константы \
#DEFINE        CR        Chr(13)
#DEFINE        CR2        CR+CR
#DEFINE        TAB        Chr(9)
#DEFINE        FAIL    -1            && возврат функций при неуспехе, неопределённое значение
****   \ "стандартные" константы /


* Крайний прессрелиз. Адрес и структура текста постоянная, надо попробовать распарсить дату следующего заседания
*   www.cbr.ru
* Описание сервиса:        www.cbr.ru
*   AllDataInfoXML    - текущая и будущая ключевая ставка, ставка рефинансирования, много другого (ответ 6 kB)
*   MainInfoXML        - только текущая ставка рефинансирования, ещё что-то (ответ 1 kB)

Function GetKeyRate        && ([cOps [,oKeyRate|dLastCheck]]) - Ключевая ставка ЦБ
LParameters cOps,oKeyRate
* cOps:
*   M    показать результат    (умолчание)
*   s    silent-режим, не выводить никаких сообщений
*   O    создать/использовать объект oKeyRate
*   o    ТОЛЬКО создать пустой объект и вернуть его, например:    GetKeyRate('o',@var)    |    var = GetKeyRate('o')
*   h    использовать "расписание" - смотри GetKeyRate_Schedule()
* oKeyRate        объект со свойствами (при O|o)
*       .nRate            текущая ставка
*       .dStart            когда она начала действовать
*       .nRate_Future    если прошло заседание - новая (будущая) ставка
*       .dStart_Future    когда начнёт действовать
*       .dLastCheck        дата последней успешной проверки
*       .dNextCheck        дата следующей проверки (для расписания)
*   объект можно создать выше [загрузить из БД]        либо    передать любую @переменную по ссылке
*   он будет изменён только при успехе
* dLastCheck    (при h) дата предыдущей успешной проверки - для расписания

* Возврат (при разных cOps):
*   o    создаст пустой объект и вернёт его
*   h    если проверка сейчас не нужна - вернёт 0
* иначе    выполнит проверку
*       если облом - вернёт FAIL
*       заполнит объект (при O)
*       вернёт текущую ставку

#DEFINE        cnURL        "http://www.cbr.ru/DailyInfoWebServ/DailyInfo.asmx"
#DEFINE        cnMethod    "AllDataInfoXML"
#DEFINE        cnByFriday    .T.        && заседания по пятница, проверяем в субботу. Иначе - раз в сутки
#DEFINE        cnMsgTitle    "Ключевая ставка ЦБ РФ"
* Разбор параметров
Local ldLastCheck        && могли передать параметром
ldLastCheck    = Iif(VarType(m.oKeyRate)="D",    m.oKeyRate,    {})
Do Case
Case VarType(m.cOps)<>"C"
    cOps        = 'M'
Case 'O' $ m.cOps    or    m.cOps='o'
    Do Case
    Case VarType(m.oKeyRate)<>"O"                && GetKeyRate('O*',@var)    |    GetKeyRate('o',@var)    |    var = GetKeyRate('o')
        oKeyRate    = CreateObject("Empty")
        AddProperty(m.oKeyRate,    "dLastCheck",    {})
    Case VarType(m.oKeyRate.dLastCheck)="D"        && GetKeyRate('O',@oKeyRate)
        ldLastCheck    = m.oKeyRate.dLastCheck
    Otherwise
        AddProperty(m.oKeyRate,    "dLastCheck",    {})
    EndCase
    * могли передать объект без нужных свойств - добавим их здесь
    = VarType(m.oKeyRate.nRate)="N"            or    AddProperty(m.oKeyRate,    "nRate",        0.00)
    = VarType(m.oKeyRate.dStart)="D"        or    AddProperty(m.oKeyRate,    "dStart",        {})
    = VarType(m.oKeyRate.nRate_Future)="N"    or    AddProperty(m.oKeyRate,    "nRate_Future",    0.00)
    = VarType(m.oKeyRate.dStart_Future)="D"    or    AddProperty(m.oKeyRate,    "dStart_Future",{})
    = VarType(m.oKeyRate.dNextCheck)="D"    or    AddProperty(m.oKeyRate,    "dNextCheck",    Date())
    If m.cOps='o'    && только создать
        RETURN m.oKeyRate
    EndIf
EndCase

* Расписание?
If 'h' $ m.cOps
    Local ldNextCheck
    ldNextCheck    = GetKeyRate_NextCheck(m.ldLastCheck)
    If m.ldNextCheck > Date()
        If 'O' $ m.cOps
            oKeyRate.dLastCheck    = m.ldLastCheck
            oKeyRate.dNextCheck    = m.ldNextCheck
        EndIf
        If 'M' $ m.cOps
            lcMsg    = "Предыдущая проверка:"    +TAB+    Transform(m.ldLastCheck)    +CR;
                    + "Сейчас проверка не выполнялась."    +CR;
                    + "Надо запланировать на:"    +TAB+    Transform(m.ldNextCheck)
            MessageBox(m.lcMsg,    64,    cnMsgTitle)
        EndIf
        Return 0    && запрос не выполняли, новых данных нет
    EndIf
EndIf

* Отправляем запрос
Local lcMsg, lcXML, loHTTP
lcMsg    = ""
Text to lcXML    TextMerge NoShow
<?xml version="1.0" encoding="utf-8"?>
<soap12:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap12="http://www.w3.org/2003/05/soap-envelope">
    <soap12:Body>
        <<"<"+cnMethod>> xmlns="http://web.cbr.ru/" />
    </soap12:Body>
</soap12:Envelope>
EndText
loHTTP    = CreateObject("MSXML2.XmlHttp")
loHTTP.Open("POST",    cnURL,    .F.)
loHTTP.SetRequestHeader("Content-Type",        "application/soap+xml; charset=utf-8")
loHTTP.SetRequestHeader("Content-length",    Transform(Len(m.lcXML)))
Try
    loHTTP.Send(m.lcXML)
Catch to lcMsg
    lcMsg    = "приводит к ошибке"    +CR+    Transform(m.lcMsg.ErrorNo)+": "+m.lcMsg.Message
EndTry
If Empty(m.lcMsg)
    Do while m.loHTTP.ReadyState<>4
        Doevents force
    EndDo
    If m.loHTTP.Status<>200
        lcMsg    = "возвращает статус"    +CR+    Transform(m.loHTTP.status)+": "+m.loHTTP.StatusText
    Else
        lcXML    = m.loHTTP.ResponseText
    EndIf
EndIf
Release loHTTP
If !Empty(m.lcMsg)
    = 's' $ m.cOps    or    MessageBox("Попытка выполнить запрос к" +CR+ cnURL +CR2+ m.lcMsg,    16,    cnMsgTitle)=0
    Return FAIL
EndIf

* Разбираем ответ
Local loXDOM
loXDOM    = CreateObject("MSXML2.DOMDocument")
loXDOM.SetProperty("SelectionLanguage", "XPath")
loXDOM.LoadXML(m.lcXML)
If m.loXDOM.ParseError.ErrorCode<>0
    lcMsg    = "Ошибка при разборе XML-ответа."
Else
    Local nRate, dStart,    nRate_Future, dStart_Future
    * <KEY_RATE Title="Действующая ключевая ставка" val="7.5" date="12.02.2018" />
    With m.loXDOM.SelectSingleNode("//KEY_RATE")
        nRate            = Val(.GetAttribute("val"))        && ValX()
        dStart            = CtoD(.GetAttribute("date"))    && VtoD()
    EndWith
    * <KEY_RATE_FUTURE Title="Новое значение ключевой ставки (справочно)" val="7.25" newdate="26.03.2018" />
    With m.loXDOM.SelectSingleNode("//KEY_RATE_FUTURE")
        nRate_Future    = Val(.GetAttribute("val"))
        dStart_Future    = CtoD(.GetAttribute("newdate"))
    EndWith
    If VarType(m.nRate)<>"N"    or    VarType(m.dStart)<>"D"    or    VarType(m.nRate_Future)<>"N"    or    VarType(m.dStart_Future)<>"D"
        lcMsg    = "В XML-ответе нет нужных данных."
    EndIf
EndIf
If !Empty(m.lcMsg)
    If !'s' $ m.cOps
        StrToFile(m.lcXML, cnMethod+".xml")
        MessageBox(m.lcMsg +CR+ "Его текст сохранён:"+CR2+ FullPathX(cnMethod+".xml"),    16,    cnMsgTitle)
    EndIf
    Return FAIL
EndIf

* Возвращаем результат
If 'O' $ m.cOps
    oKeyRate.nRate            = m.nRate
    oKeyRate.dStart            = m.dStart
    oKeyRate.nRate_Future    = m.nRate_Future
    oKeyRate.dStart_Future    = m.dStart_Future
    oKeyRate.dLastCheck        = Date()
    oKeyRate.dNextCheck        = GetKeyRate_NextCheck(Date())
EndIf
If 'M' $ m.cOps
    lcMsg        = "Текущая ставка:"        +TAB+    Transform(m.nRate)    +CR;
                + "начало действия:"    +TAB+    Transform(m.dStart)
    If m.dStart_Future>m.dStart
        lcMsg    = m.lcMsg    +CR2;
                + "Новая ставка:"        +TAB+    Transform(m.nRate_Future)    +Iif(m.nRate_Future=m.nRate,TAB+"(не меняется)","")    +CR;
                + "начало действия:"    +TAB+    Transform(m.dStart_Future)
    Else
        lcMsg    = m.lcMsg    +CR2+    "О следующем изменении информация отсутствует."
    EndIf
    lcMsg        = m.lcMsg    +CR2;
                + "Надо проверить:"        +TAB+    Transform(Iif('O' $ m.cOps,    m.oKeyRate.dNextCheck,    GetKeyRate_NextCheck(Date())))
    MessageBox(m.lcMsg,    64,    cnMsgTitle)
EndIf
Return m.nRate
*---------------------------------------------------------------------------

Function GetKeyRate_NextCheck    && (dLastCheck) - дата следующей проверки
LParameters dLastCheck
#IF !cnByFriday            && ежедневная проверка:    если сегодня проверяли, планируем на завтра
    Return Iif(VarType(m.dLastCheck)="D" and m.dLastCheck=Date(),    Date()+1,    Date())
#ELSE    && проверка по субботам
    * Здесь предполагается, что ЦБ гуляет по пятницам (13:30 МСК). Проверяем в субботу и дальше
    * Хорошо бы знать дату следующего заседания - тогда проверять можно раз в месяц-полтора
    If VarType(m.dLastCheck)<>"D"    or    m.dLastCheck={}    or    m.dLastCheck>Date()
        Return Date()
    EndIf
    Local lnDays            && прошло дней с предыдущей проверки
    lnDays    = Date() - m.dLastCheck
    Do Case
    Case m.lnDays=0            && сегодня уже проверяли
    Case m.lnDays>6            && прошла неделя или больше
        Return Date()
    Case m.lnDays<0            && чушь
        Return Date()
    Case Week(m.dLastCheck) = Week(Date())        && проверяли на этой неделе
        If DoW(m.dLastCheck,2)<6    and    DoW(Date(),2)>=6
            Return Date()    && проверяли до субботы, а уже суббота - надо проверить, вдруг вчера изменилась
        EndIf
    Case DoW(m.dLastCheck,2)<6    && на предыдущей неделе, до субботы
        Return Date()
    EndCase
    * планируем на субботу на этой неделе
    Local ldThisSabbath
    ldThisSabbath    = Date() - DoW(Date(),2) + 6
    If Date()>=m.ldThisSabbath
        * суббота уже наступила, но раз сюда попали, значит, после пятницы уже проверяли
        * поэтому проверим в следующую субботу
        Return m.ldThisSabbath + 7
    EndIf
    Return m.ldThisSabbath
#ENDIF
#UNDEFINE    cnURL
#UNDEFINE    cnMethod
#UNDEFINE    cnByFriday
#UNDEFINE    cnMsgTitle

* вариант вызова: 1-5
i    = 1

FAIL    = -1
fn    = AddBS(JustPath(sys(16))) + "CBRF.prg"
Set Procedure to (m.fn) additive
t    = Seconds()
? "----    "
Local loKeyRate
Do Case    
Case m.i=1    && получить, показать результат
    GetKeyRate()
    Return
Case m.i=2    && расписание, показать результат
    GetKeyRate('Mh', Date()-1)
    Return
Case m.i=3    && записать результат в объект
    If GetKeyRate('O', @m.loKeyRate) = FAIL
        i    = FAIL
    EndIf
Case m.i=4    or    m.i=5    && сначала создать пустой объект
    If m.i=3
        loKeyRate    = GetKeyRate('o')
    Else    && то же самое
        GetKeyRate('o', @m.loKeyRate)
    EndIf
    loKeyRate.dLastCheck    = Date()-10
    ? "создали пустой объект, записали в него значения предыдущей проверки"
    If GetKeyRate('Oh', @m.loKeyRate) = FAIL
        i    = FAIL
    EndIf
Otherwise
    i    = FAIL
EndCase
t    = Seconds() - m.t
If m.i=FAIL
    ? "косяк"
Else
    With m.loKeyRate
        ? .dStart,    .nRate
        ? .dStart_Future,    .nRate_Future
        ? .dLastCheck,    TAB,    "последняя успешная"
        ? .dNextCheck,    TAB,    "когда планировать"
    EndWith
EndIf
Release m.loKeyRate
? "----",    Int(m.t*1000),    " мс"
Release Procedure (m.fn)
RETURN