CLEAR
        Declare Integer GetProcessHeap in Win32API    
        Declare Integer HeapAlloc in Win32Api Integer, Integer, Integer    
        Declare RtlMoveMemory in Win32API Integer, String, Integer    
SET SAFETY Off  
    
  m.str = REPLICATE("0123456789", 10^5)  && 10^5 - 1 МБайт
    
  m.sc = SEConds()  
  ? "на ассеблере: "
  m.rev = RevertString(m.str)  && очень быстро, нет слов, 0.02 сек
  ??SECONDS() - m.sc
  ?  
    
  m.sc = SEConds()  
  ? "на SYS(2600): "
  m.rev = RevertString2600(m.str)  && SYS(2600 - 0.5 сек (на порядок медленнее ассеблера, но тоже хорошо)
  ??SECONDS() - m.sc
  ?  

  m.sc = SEConds()  
  ? "на FWRITE: "
  m.rev = rev_str2(m.str)   && более-менее быстро - 3 сек
  ??SECONDS() - m.sc  
  ?

  m.sc = SEConds()  
  ? "просто SUBSTR: "
  m.rev = rev_str1(m.str, 1)  && оказалось, что SUBSTR выполняется столько же медленно (что с конкатенацией, что без), странно... 50 сек
  ??SECONDS() - m.sc  
  ?

  m.sc = SEConds()  
  ? "на x = x+SUBSTR: "
  m.rev = rev_str1(m.str)  && тоже 50 сек...
  ??SECONDS() - m.sc  
  ?
    

 Function RevertString2600    && на SYS(2600
    lparameter m.str    
    PRIVATE ALL LIKE ?
    m.l = len(m.str)  && длина входной строки

      m.h = GetProcessHeap() 
      m.p = HeapAlloc(m.h, 0, 2 * (m.l+16)) && место для входной и выходной строк. Выходная строка будет начинаться с позиции m.l
      RtlMoveMemory(m.p, m.str, m.l)  && заполняем первые L байт входной строкой
      
      #DEFINE iБайтИсходнойСтроки  SYS(2600, m.p+m.i, 1)  && I = 0..L-1
      FOR m.i=0 TO m.l-1
      * =m.p+m.l+(m.l-m.i-1)
          =SYS(2600, m.p+m.l+(m.l-m.i-1), 1, iБайтИсходнойСтроки)  && записываем байт I в выходную строку
      ENDFOR
      m.r = SYS(2600, m.p+m.l, m.l)  && выходная строка
      * ? "образец: "+LEFT(m.r, 100)  && немного посмотреть
      RETURN m.r


  FUNCTION rev_str1  && на x = x+SUBSTR
    lparameter m.str, m.parDOP  
    local m.str2, m.i
    IF PCOUNT()<2  && SUBSTR с конкатенацией строк
       m.str2 = ''    
       for m.i = len( m.str ) to 1 step -1    
         m.str2 = m.str2 + substr( str, m.i, 1 )    
       endfor  
    ELSE  && просто посмотреть SUBSTR без конкатенации
       for m.i = len( m.str ) to 1 step -1    
         =substr( str, m.i, 1 )    
       endfor  
    ENDIF
    
  FUNCTION rev_str2  && на FWRITE
    lparameter m.str    
    local m.str2, m.i, m.str_len, m.hnd1, m.hnd2  
    m.str_len=len(m.str)  
    if m.str_len=0    
        return ""    
    endif    
    m.str2 = REPLICATE(CHR(0), m.str_len)  
    STRTOFILE(m.str, "str.txt")  
    STRTOFILE(m.str2, "str2.txt")  
    m.hnd1 = FOPEN("str.txt", 0)  
    m.hnd2 = FOPEN("str2.txt", 1)  
    FOR m.i = 1 TO m.str_len  
      FSEEK(m.hnd1, m.str_len - m.i)  
        FWRITE(m.hnd2, FREAD(m.hnd1, 1))  
    NEXT  
    FCLOSE(m.hnd1)  
    FCLOSE(m.hnd2)  
    m.str2 = FILETOSTR("str2.txt")  
    RETURN m.str2  
    
  Function RevertString    && на ассемблере
    lparameter m.str    
    local m.str_len, m.str1    
    m.str_len=len(m.str)    
    if m.str_len=0    
        return ""    
    endif    
        
        
    if !pemstatus(_screen,"revw_ptr",5) or _screen.revw_ptr=0    
        
        local m.hhnd, m.ptr, m.st2    
        
        m.st2= ;    
            chr(0x55)+chr(0x89)+chr(0xE5)+chr(0x56)+chr(0x57)+chr(0x51)+chr(0x50)+chr(0x8B)+ ;    
            chr(0x75)+chr(0x08)+chr(0x8B)+chr(0x7D)+chr(0x0C)+chr(0x8B)+chr(0x4D)+chr(0x10)+ ;    
            chr(0x8A)+chr(0x44)+chr(0x0E)+chr(0xFF)+chr(0x88)+chr(0x07)+chr(0x47)+chr(0x49)+ ;    
            chr(0x75)+chr(0xF6)+chr(0x58)+chr(0x59)+chr(0x5F)+chr(0x5E)+chr(0x89)+chr(0xEC)+ ;    
            chr(0x5D)+chr(0xC2)+chr(0x10)+chr(0x00)    
        m.hhnd=GetProcessHeap()    
        m.ptr=HeapAlloc(m.hhnd,0,len(m.st2)+16) && место для кода   
        RtlMoveMemory(m.ptr,m.st2,len(m.st2))   && код
        _screen.addproperty("revw_ptr",m.ptr)   && адрес кода
    endif    
        
    m.str1=replicate(chr(0), m.str_len)   && место для выходной строки 
        
    Declare CallWindowProc in Win32API Integer, String, String @, Integer, Integer    
        
    CallWindowProc(_screen.revw_ptr, m.str, @m.str1, m.str_len, 0)    && выполняем код
        
    return m.str1  && на ассемблере