LPARAMETERS cHost, nPort, nTimeOut
* cHost  удалённый хост, имя или IP в интернет-нотации, строка
* nPort  удалённый порт, число
* nTimeOut тайм-аут приема и передачи

IF EMPTY(nTimeOut)
    nTimeOut = 5
ENDIF

LOCAL lRet, cBuf, nRetVal, nSockHandler, nSize, InBufSize, cBinIP, InBufSize, OutBufSize
* Подготовить приложение к использованию Winsock
cBuf = REPLICATE(CHR(0),WSADATA_SIZE)
nRetVal = WSAStartup(WS_VERSION,@cBuf)
IF nRetVal <> 0
    ERROR 1
ELSE
    This.WSAStarted = .T.
ENDIF

* Создать сокет
nSockHandler = socket(AF_INET,SOCK_STREAM,IPPROTO_TCP)
IF nSockHandler = 0
    ERROR 1
    RETURN -1
ELSE
    This.hSocket = nSockHandler
* Если сокет создан успешно, определить размер его буфера приема
    cBuf = REPLICATE(CHR(0),4)
    nSize = 4
    IF getsockopt(nSockHandler,SOL_SOCKET,SO_RCVBUF,@cBuf,@nSize) = SOCKET_ERROR
        ERROR 1
        RETURN -1
    ENDIF
    InBufSize = CTOBIN(CREATEBINARY(SUBSTR(cBuf,1,nSize)),TRANSFORM(nSize)+'RS')
    IF InBufSize <=0
        ERROR 1
        RETURN -1
    ELSE
        This.RecvBufferSize = InBufSize
    ENDIF
    OutBufSize = CTOBIN(CREATEBINARY(SUBSTR(cBuf,1,nSize)),TRANSFORM(nSize)+'RS')
    IF OutBufSize <=0
        ERROR 1
        RETURN -1
    ELSE
        This.SendBufferSize = OutBufSize
    ENDIF
ENDIF

cBinIP = This.getbinip(cHost)
IF EMPTY(cBinIP)
    RETURN -1
ENDIF
cBuf = BINTOC(AF_INET,'2SR') + BINTOC(nPort,'2S') + cBinIP + REPLICATE(CHR(0),8)
lRet = connect(nSockHandler, @cBuf, LEN(cBuf))
IF  lRet = SOCKET_ERROR
    ERROR 1
    RETURN -1
ENDIF

RETURN This.SetTimeout(nTimeOut)