APPEND MEMO MemoFieldName FROM FileName[OVERWRITE] [AS nCodePage]

*-- API32-functions for INI-files **************************************
DECLARE Integer WritePrivateProfileString IN WIN32API as WritePrivStr ;
String cSection, ;     && Имя раздела
String cKey, ;        && Имя реквизита
String cValue, ;    && Значение реквизита
String posfile        && Имя INI-файла с полным путем доступа

DECLARE Integer GetPrivateProfileString IN WIN32API as GetPrivStr ;
String cSection, ;     && Имя раздела
String cKey, ;        && Имя реквизита
String cDefault, ;    && Значение по умолчанию
String @CBufer, ;    && Считанное значение реквизита
Integer nBufferSize, ;    && Макс. число симоволов в счит. реквизите
String posfile        && Имя INI-файла с полным путем доступа
*************************************************************************

        
lcFile        = '..\myinifile.ini'        + chr(0)
lcBufer        = repli( ' ', 256 )
lcSection    = 'MySection'    + chr(0)
lcKey        = 'MyKey'    + chr(0)
n = GetPrivStr( m.lcSection, m.lcKey, "", @lcBufer, 255, m.lcFile)
if m.n>0
   lcResult = left( m.lcBufer, m.n )
else
   * что-то пошло не так
endif

* Забираем данные ини файла в курсор для дальнейшей обработки.
inifile=Getfile('INI')
If ini_to_cursor(iniFile)
browse
Endif
Return .T.

*********************************************
* Function ini_to_cusor(iniFileName)
*********************************************
Function ini_to_cursor
Lparameters lcFileName
If Parameters( )=0
    Messagebox('Не найден параметр {lcFileName.ini}')
    Return .F.
Endif
If !File(lcFileName)
    Messagebox('Не найден файл:'+Chr(10)+Chr(13)+lcFileName)
    Return .F.
Endif
Local m.lcini,m.lRet, m.lcBuffer,m.lcStrok, m.lcSection,m.lckey,m.lcValue,m.lcComment,m.Strlen,m.AtNum
m.lcini=Juststem(lcFileName)
m.lRet=Chr(10)
m.lcBuffer=m.lRet+Filetostr(lcFileName)
m.lcStrok=''
m.lcSection=''
m.lckey=''
m.lcValue=''
m.lcComment=''
m.Strlen=0
m.AtNum=0
* Создаём курсор.
Create Cursor &lcini(lcini c(32),lcSection c(32),lckey c(32),lcValue c(64),lcComment c(254))
* Анализируем построчно разделитель m.lRet=Chr(10).
For m.lnI = 1 To Occurs(m.lRet,m.lcBuffer)-1
    m.lcValue=''
    lnFromPos = At(m.lRet,m.lcBuffer,m.lnI)
    lnToPos = At(m.lRet,m.lcBuffer,m.lnI+1)
    m.lcStrok=Substr(m.lcBuffer,m.lnFromPos+1,m.lnToPos-m.lnFromPos-1)
    m.Strlen=Len(m.lcStrok)
* Номер позиции знака ';' в строке.
    m.AtNum=At(';',m.lcStrok,1)
    If m.AtNum>0
* Убираем и запоминаем коментарий за знаком ';'
        m.lcComment=Alltrim(Substr(m.lcStrok,m.AtNum+1,m.Strlen-m.AtNum+1))
        m.lcStrok=Left(m.lcStrok,m.AtNum-1)
        m.Strlen=Len(m.lcStrok)
    Else
        m.lcComment=''
    Endif
    If  Left(m.lcStrok,1)='['
        m.lcSection=Alltrim(Left(m.lcStrok,At(']',m.lcStrok,1)))
    Else
* Номер позиции знака '=' в строке.
        m.AtNum=At('=',m.lcStrok,1)
        If  m.AtNum>0
* До знака '=' в переменную ключ.
            m.lckey=Alltrim(Left(m.lcStrok,m.AtNum-1))
* После знака '=' в переменную Значение.
            m.lcValue =Alltrim(Substr(m.lcStrok,m.AtNum+1,m.Strlen-m.AtNum+1))
        Endif
    Endif
    If Len(m.lcValue)>0
*?"Секция "+m.lcSection,"Ключ "+m.lckey,"Значение "+m.lcValue,"Коментарий "+m.lcComment
        Append Blank
        Gather Memvar
    Endif
Endfor
Return .T.
Endfunc

DECLARE INTEGER GetPrivateProfileSectionNames IN WIN32API ;
        STRING @ lpszReturnBuffer, ;
        INTEGER nSize, ;
        STRING lpFileName
DECLARE INTEGER GetPrivateProfileSection IN WIN32API ;
        STRING lpAppName, ;
        STRING @ lpReturnedString, ;
        INTEGER nSize, ;
        STRING lpFileName