* курсор масок:
CREATE CURSOR ctmp (fld1 c(3), fld2 c(3), fld3 c(3))
INSERT INTO ctmp VALUES ('003', '034', '001')
INSERT INTO ctmp VALUES ('088', '002', '001')
INSERT INTO ctmp VALUES ('001', '088', '002')
INDEX ON fld1 TAG fld1

cPath1 = "c:\test\in\"
cPath2 = "c:\test\out\"

* создание структуры файлов-папок для теста:
MD (cPath1)
MD (cPath2)
TEXT TO cFiles
qW-003-034.txt
rT-034-055.txt
Fi-088-002.txt
uO-001-088.txt
YI-499-546.txt
ENDTEXT 
FOR lni=1 TO GETWORDCOUNT(cFiles)
  COPY TO (cPath1 + GETWORDNUM(cFiles,lni)) SDF 
ENDFOR 
* создание структуры для теста вообще говоря, тебе надо было бы самому сразу привести, чтобы все видели образец!

* ну и собственно само копирование:
***

oFSO = CREATEOBJECT("Scripting.FileSystemObject") 
SCAN
  cFileName1 = "??-" + fld1 + "-" + fld2 + ".txt"
  oFSO.CopyFile(cPath1+cFileName1, cPath2)
ENDSCAN

oFolder = oFSO.GetFolder(cPath2)
FOR EACH File In oFolder.Files
  IF SEEK(SUBSTR(File.Name,4,3))
    File.Name = STUFF(File.Name,8,3,fld3)
  ENDIF 
NEXT

***

oFSO = CREATEOBJECT("Scripting.FileSystemObject")   
  SCAN  
    cFileName1 = "??-" + fld1 + "-" + fld2 + ".txt"  
    oFSO.CopyFile(cPath1+cFileName1, cPath2)  
  ENDSCAN  
    
  oFolder = oFSO.GetFolder(cPath2)  
  FOR EACH File In oFolder.Files  
    IF SEEK(SUBSTR(File.Name,4,3))  
      File.Name = STUFF(File.Name,8,3,fld3)  
    ENDIF   
  NEXT

*
* Действие над файлами
*  tnHWND - дискриптор окна
*  tcFrom - спецификация исходных файлов (можно указывать звёздочки и "?")  
*  tcTo   - спецификация результирующих файлов (папки)  
*  tnOper - определяет тип операции.  
*        tnOper=1 - переместить файлы  
*        tnOper=2 - копировать файлы  
*        tnOper=3 - удалить файлы  
*        tnOper=4 - переименовать файл  
*  
FUNCTION FileOperation  
  LPARAMETER tnHWND, tcFrom, tcTo, tnOper  

  LOCAL lcSHFO, lcFrom, lnLenFrom, lcTo, lnLenTo, hGlobalFrom, hGlobalTo  
  LOCAL lnFlag, lnReturn  
  DECLARE Long SHFileOperation IN Shell32.dll String @
  DECLARE Long DeleteFile IN kernel32.dll String @
  
  DECLARE Long GlobalAlloc IN WIN32API Long, Long  
  DECLARE Long GlobalFree IN WIN32API Long
 *  
 * Начинаем формировать структуру в переменной lcSHFO  
 * 
     *_screen.HWnd
  * lcSHFO = BINTOC(thisform.HWnd, '4RS')      && Поле hwnd структуры  
  lcSHFO = BINTOC(tnHWND, '4RS')      && Поле hwnd структуры
  lcSHFO = lcSHFO + BINTOC(tnOper, '4RS')    && Поле wFunc - вид операции   
 *  
 * Обработка спецификации исходных файлов  
 *  
  tcFrom = tcFrom + CHR(0) + CHR(0)             && Дописываем нули  
  lnLenFrom = LEN(tcFrom)                       && Длина исходной строки  
  hGlobalFrom = GlobalAlloc(0x0040, lnLenFrom)  && Выделяем для неё  
                                                && блок памяти  
  SYS(2600, hGlobalFrom, lnLenFrom, tcFrom)     && и копируем туда строку  
  lcSHFO = lcSHFO + BINTOC(hGlobalFrom, '4RS')  && Поле pFrom  
 *  
 * Обработка спецификации результирующих файлов  
 *  
  IF tnOper = 3  
      lcSHFO = lcSHFO + BINTOC(0, '4RS') && Если операции удаления  
  ELSE  
      tcTo = tcTo + CHR(0) + CHR(0)      && Дописываем нули  
      lnLenTo = LEN(tcTo)                && Длина результирующей строки  
      hGlobalTo = GlobalAlloc(0x0040, lnLenTo)   && Выделяем для неё  
                                                 && блок памяти  
      SYS(2600, hGlobalTo, lnLenTo, tcTo)        && и копируем туда строку  
      lcSHFO = lcSHFO + BINTOC(hGlobalTo, '4RS') && Поле pTo структуры  
  ENDIF  
  lnFlag = 8 + 512  
  lcSHFO = lcSHFO + BINTOC(lnFlag, '2RS') && Поле fFlags структуры  
  lcSHFO = lcSHFO + REPLICATE(CHR(0), 12) && Последние 3 поля структуры  
 *  
 * Выполняем операцию  
 *
 IF tnOper = 3
     lnReturn = DeleteFile(@tcFrom)
     IF lnReturn > 0
         lnReturn = 0
     ELSE
         lnReturn = -1
     ENDIF
 ELSE
     lnReturn = SHFileOperation(@lcSHFO)  
 ENDIF
 *  
 * Возвращаем память Windows  
 *  
  GlobalFree(hGlobalFrom)  
  IF tnOper != 3  
      GlobalFree(hGlobalTo)  
  ENDIF  
 *  
 * Если lnReturn = 0, то операция завершена успешно  
 *  
  IF lnReturn != 0  
      RETURN .f.  
  ENDIF  
  RETURN .t.