oForm=CreateObject("Form1")
oForm.Show(1)
Define Class Form1 as Form
    AutoCenter=.T.
    WindowType=1
    
    Add Object cmdButton as CommandButton with ;
        Left=100,;
        Top=100,;
        Height=25,;
        Width=100,;
        Caption='Close'
        
    Procedure cmdButton.Click
    thisform.Release()
    Procedure Load
    Define Popup ModalPopup Relative 
    Define Pad ModalPad of _MSYSMENU Prompt 'Form1' ;
        Skip For ;
        iif(type('_screen.activeform')='O' ;
        and pemstatus(_screen.activeform,'ModalMenu',5),;
        _screen.activeform.modalmenu(),.T.)
    on pad modalpad of _msysmenu activate popup ModalPopup
    on selection popup ModalPopup _screen.activeform.ModalMenuSelection(Bar())
        
    Procedure ModalMenu
    * !* Если убрать комментарий в конце строки - ошибка
    Define Bar 1 of ModalPopup prompt 'One' && pictres _MFI_NEW
    Define Bar 2 of ModalPopup prompt 'Two'
    Define Bar 3 of ModalPopup prompt 'Three'
    Define Bar 4 of ModalPopup prompt '\-'
    Define Bar 5 of ModalPopup prompt 'Five'
    *** always return .F.
    Return .F.                
    
    Procedure ModalMenuSelection(nBar)
    MessageBox("Modal menu selected bar # "+str(nBar),64,this.caption)
    Procedure Destroy
    Release Pad ModalPad of _msysmenu
    Release popup ModalPopup Extended
EndDefine

Procedure GotFocus
      Define Popup ModalPopup MARGIN RELATIVE SHADOW COLOR SCHEME 4
      Define Pad ModalPad of _MSYSMENU Prompt 'Form1'   
      Define Bar 1 of ModalPopup prompt 'One' PICTRES _mfi_new 
      Define Bar 2 of ModalPopup prompt 'Two'  
      Define Bar 3 of ModalPopup prompt 'Three'  
      Define Bar 4 of ModalPopup prompt '\-'  
      Define Bar 5 of ModalPopup prompt 'Five'  
      on pad modalpad of _msysmenu activate popup ModalPopup  
      on selection popup ModalPopup _screen.activeform.ModalMenuSelection(Bar())  
     *** always return .F.  
      Return .F.