* Формирование SQL-файла с командами INSERT на основании DBF-таблицы
* tcDbfname  - имя DBF-таблицы
* tnRecnum   - начальный номер записи (0 или не число - вся таблица)
* tnPartsize - максимальное количество команд INSERT в одном SQL-файле (не число - не ограничено)
PROCEDURE dbf2sql
PARAMETERS tcDbfname, tnRecnum, tnPartsize

SET TALK OFF
SET STATUS OFF
SET DELETED ON
SET DATE GERMAN
SET CENTURY ON
SET NULL ON
SET ANSI ON
SET EXACT ON

LOCAL lnSql                    && SQL-файл
LOCAL llSqlopen                    && Признак открытия SQL-файла
LOCAL lnPartnum                    && Счетчик SQL-файлов
LOCAL lcPartname                && Метка номера SQL-файла в имени
LOCAL lnInpart                    && Счетчик записей в SQL-файле
LOCAL lcInsert                    && Одна команда INSERT (постоянная часть)
LOCAL lcValues                    && Одна команда INSERT (значения полей)
LOCAL laField[1]                && Список полей DBF-таблицы
LOCAL laNames[1]                && Список длинных имен полей DBF-таблицы
LOCAL lnIfield                    && Счетчик полей DBF-таблицы
LOCAL lnNfield                    && Количество полей DBF-таблицы
LOCAL lcName                    && Имя поля DBF-таблицы
LOCAL luValue                    && Значение поля DBF-таблицы

CLOSE DATABASES
USE (tcDbfname) IN 0 NOUPDATE ALIAS dbffile
IF FILE('sqlnames.DBF')
    USE sqlnames IN 0 NOUPDATE
ENDIF
IF USED('dbffile')
    lnNfield = AFIELDS(laField,'dbffile')
    DIMENSION laNames[lnNfield]
    lcInsert = 'INSERT INTO '+tcDbfname+' ('
    FOR lnIfield=1 TO lnNfield
        laNames[lnIfield] = LOWER(laField[lnIfield,1])
        IF LEN(laNames[lnIfield])=10 AND USED('sqlnames')
            SELECT sqlnames
            LOCATE FOR ALLTRIM(tablename)==tcDbfname AND;
                (shortname==laNames[lnIfield] OR (EMPTY(shortname) AND;
                LEFT(fieldname,10)==laNames[lnIfield]))
            IF FOUND()
                laNames[lnIField] = ALLTRIM(sqlnames.fieldname)
            ENDIF
        ENDIF
        lcInsert = lcInsert+IIF(lnIfield>1,', ','')+tcDbfname+laNames[lnIfield]
    ENDFOR
    lcInsert = lcInsert+') VALUES ('
    IF TYPE('tnRecnum')='N' AND !EMPTY(tnRecnum)
        GO tnRecnum IN dbffile
    ELSE
        GO TOP IN dbffile
    ENDIF
    llSqlopen = .F.
    lnPartnum = 0
    DO WHILE !EOF('dbffile')
        IF !llSqlopen
            lnPartnum  = lnPartnum+1
            lcPartname = IIF(TYPE('tnPartsize')='N','_'+;
                CHRTRAN(STR(lnPartnum,3),' ','0'),'')
            lnSql = FCREATE('import_'+tcDbfname+lcPartname+'.sql')
            IF lnSql<0
                EXIT
            ENDIF
            =FPUTS(lnSql,STRCONV([SET statement_timeout = 0;],9))
            =FPUTS(lnSql,STRCONV([SET client_encoding = 'UTF8';],9))
            =FPUTS(lnSql,STRCONV([SET standard_conforming_strings = on;],9))
            =FPUTS(lnSql,STRCONV([SET check_function_bodies = false;],9))
            =FPUTS(lnSql,STRCONV([SET client_min_messages = warning;],9))
            =FPUTS(lnSql,STRCONV([SET search_path = public, pg_catalog;],9))
            llSqlopen = .T.
            lnInpart  = 0
        ENDIF
        lcValues = ''
        FOR lnIfield=1 TO lnNfield
            lcValues = lcValues+IIF(lnIfield>1,', ','')
            lcName   = 'dbffile.'+laField[lnIfield,1]
            DO CASE
                CASE ISNULL(&lcName)
                    lcValues = lcValues+'NULL'
                CASE laField[lnIfield,2]='C' OR laField[lnIfield,2]='M'
                    luValue = ALLTRIM(&lcName)
                    IF LEN(luValue)>=3 AND LEFT(luValue,3)=='GEO'
                        lcValues = lcValues+luValue
                    ELSE
                        lcValues = lcValues+[']+luValue+[']
                    ENDIF
                CASE laField[lnIfield,2]='D'
                    luValue  = DTOS(&lcName)
                    lcValues = lcValues+[']+SUBSTR(luValue,1,4)+[-]+;
                        SUBSTR(luValue,5,2)+[-]+SUBSTR(luValue,7,2)+[']
                CASE laField[lnIfield,2]='T'
                    luValue  = TTOC(&lcName,3)
                    lcValues = lcValues+[']+SUBSTR(luValue,1,10)+[ ]+;
                        SUBSTR(luValue,12,8)+[']
                CASE laField[lnIfield,2]='L'
                    luValue  = IIF(&lcName,'true','false')
                    lcValues = lcValues+luValue
                CASE laField[lnIfield,2]='N'
                    IF laField[lnIfield,4]>0
                        luValue = ALLTRIM(STR(&lcName,laField[lnIfield,3],;
                            laField[lnIfield,4]))
                    ELSE
                        luValue = ALLTRIM(STR(&lcName,laField[lnIfield,3]))
                    ENDIF
                    lcValues = lcValues+luValue
            ENDCASE
        ENDFOR
        =FPUTS(lnSql,STRCONV(lcInsert+lcValues+');',9))
        lnInpart = lnInpart+1
        IF TYPE('tnPartsize')='N' AND lnInpart>=tnPartsize
            =FCLOSE(lnSql)
            llSqlopen = .F.
        ENDIF
        SKIP IN dbffile
    ENDDO
    IF llSqlopen
        =FCLOSE(lnSql)
        llSqlopen = .F.
    ENDIF
ENDIF
CLOSE DATABASES
RETURN

=FPUTS(lnHandle,[INSERT INTO mytable VALUES (]+STRTRAN(lcValue,[''],['+"'"+'])+[)]

lnHandle = SQLSTRINGCONNECT("DRIVER=Firebird/InterBase(r) driver; DBNAME=d:\mydir\myfile.GDB;UID=SYSDBA;PWD=masterkey")